0  BEGIN PGM 5085-DE MM 
1  ;In diesem Programm werden, auf einer
2  ;geschwenkten Ebene, ein
3  ;Kreiszapfen und eine Kreistasche bearbeitet
4  ;und anschliessend fraest man mit einem
5  ;angestellten Werkzeug umlaufend eine Fase
6  ;an die Konturen. Die Konturen programmieren Sie
7  ;mit Zyklen. Fuer die Fasen muessen Sie die
8  ;die Parameter definieren, aus denen die
9  ;Steuerung die Werkzeugbahnen berechnet.
10 ;
11 BLK FORM 0.1 Z X-50 Y-50 Z-40
12 BLK FORM 0.2  X+50  Y+50  Z+10
13 TOOL CALL 8 Z S12000 F5000 ;Fraeser D16
14 * - Bearbeitungsebene schwenken
15 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
16 CYCL DEF 232 PLANFRAESEN ~
    Q389=+1    ;STRATEGIE ~
    Q225=-50   ;STARTPUNKT 1. ACHSE ~
    Q226=-60   ;STARTPUNKT 2. ACHSE ~
    Q227=+20   ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+100  ;1. SEITEN-LAENGE ~
    Q219=+120  ;2. SEITEN-LAENGE ~
    Q202=+20   ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
17 M3 M99
18 CYCL DEF 252 KREISTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+60   ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+500  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-10   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
19 L  X+0  Y+0 R0 FMAX M3 M99
20 CYCL DEF 257 KREISZAPFEN ~
    Q223=+100  ;FERTIGTEIL-DURCHM. ~
    Q222=+142  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+500  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-10   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=-1    ;STARTWINKEL
21 L  X+0  Y+0 R0 FMAX M3 M99
22 ;
23 * - Fase Parameter
24 Q1 = 5 ;FASENLAENGE
25 Q2 = 45 ;FASENWINKEL
26 Q3 = 100 ;D KREIS
27 Q4 = 1 ;BEARBEITUNG: 1=AUSSEN 2=INNEN
28 TOOL CALL  DL-0.5 ;Ueberlauf um saubere Fasenunterkante zu bekommen
29 CALL LBL "fase"
30 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
31 ;
32 * - Fase Parameter
33 Q1 = 5 ;FASENLAENGE
34 Q2 = 45 ;FASENWINKEL
35 Q3 = 60 ;D KREIS
36 Q4 = 2 ;BEARBEITUNG: 1=AUSSEN 2=INNEN
37 TOOL CALL  DL-0.5 ;Ueberlauf um saubere Fasenunterkante zu bekommen
38 CALL LBL "fase"
39 ;
40 M2
41 LBL "fase"
42 ;Abfrage aussen oder innen
43 FN 9: IF +Q4 EQU +2 GOTO LBL "innen"
44 FN 9: IF +Q4 EQU +1 GOTO LBL "aussen"
45 STOP
46 ;Bitte Q4 waehlen aussen oder innen
47 ;
48 LBL "innen"
49 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
50 Q10 = Q108 * ( COS Q2 ) ;Berechne WZR-Korrektur Radius
51 Q11 = ( Q3 / 2 ) - Q10 ;Durchmesser - WZR-Korrektur Radius
52 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;WZR-Korrektur Z
53 QL11 = Q11 - Q108 ;Anfahrposition Y
54 QL12 = Q12 - 2 ;Anfahrposition Z
55 L  X-Q108  Y-QL11  Z+50 R0 FMAX
56 L  A+Q2  B+0  C+0 R0 FMAX ;Wichtig alle drei Rundachsen wegen TCPM ... AXIS SPAT
57 L  Z-QL12 R0 F AUTO
58 CC  X+0  Y-QL11
59 CP  PA-90  Z-Q12 DR+
60 QL1 = 270
61 LBL 1
62 QL1 = QL1 + 1
63 QL2 = Q11 * COS QL1
64 QL3 = Q11 * SIN QL1
65 L  X+QL2  Y+QL3 IC+1
66 CALL LBL 1 REP359
67 CC  X+0  Y-QL11
68 CP  PA+0  Z-QL12 DR+
69 M140 MB+20
70 FN 9: IF +0 EQU +0 GOTO LBL "reset"
71 ;
72 LBL "aussen"
73 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
74 Q10 = Q108 * ( COS Q2 ) ;Berechne WZR-Korrektur Radius
75 Q11 = ( Q3 / 2 ) + Q10 ;Durchmesser + WZR-Korrektur Radius
76 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;WZR-Korrektur Z
77 QL11 = Q11 + Q108 ;Anfahrposition Y
78 QL12 = Q12 - 2 ;Anfahrposition Z
79 L  X+Q108  Y-QL11  Z+50 R0 FMAX
80 L  A-Q2  B+0  C+0 R0 FMAX ;Wichtig alle drei Rundachsen wegen TCPM ... AXIS SPAT
81 L  Z-QL12 R0 F AUTO
82 CC  X+0  Y-QL11
83 CP IPA+90  Z-Q12 DR+
84 QL1 = 270
85 LBL 2
86 QL1 = QL1 - 1
87 QL2 = Q11 * COS QL1
88 QL3 = Q11 * SIN QL1
89 L  X+QL2  Y+QL3 IC-1
90 CALL LBL 2 REP359
91 CC  X+0  Y-QL11
92 CP  PA+180  Z-QL12 DR+
93 M140 MB+20
94 ;
95 LBL "reset"
96 FUNCTION RESET TCPM
97 * - Sichere Position anfahren
98 L  Z+500 R0 FMAX M91
99 L  X+800  Y+600 R0 FMAX M91
100 * - Bearbeitungsebene zurueckschwenken
101 PLANE RESET TURN FMAX
102 LBL 0
103 END PGM 5085-DE MM