0 BEGIN PGM 1010_ES MM 
1 ;Programa para la definición de un patrón de puntos
2 ;en forma de una elipse. Para el mecanizado se
3 ;llama un ciclo de mecanizado en las posiciones
4 ;calculadas. En este programa un ciclo de taladrado,
5 ;con el que primeramente se centra y, a continuación,
6 ;se taladra. Tras la definición de todos los
7 ;parámetros que se precisan, de la herramienta y del
8 ;ciclo de mecanizado se llama un subprograma. En el
9 ;mismo tiene lugar primeramente un cálculo de la
10 ;trayectoria completa de la elipse. Ésta se compone
11 ;de coordenadas X e Y individuales. La distancia de
12 ;los puntos individuales, y con ello la precisión
13 ;de la trayectoria, se determina mediante el
14 ;parámetro Q5=Paso angular, que establece el ángulo
15 ;entre dos puntos. Después de haberse calculado el
16 ;contorno completo, se determinan las posiciones de
17 ;mecanizado individuales, se hace la aproximación a
18 ;las mismas y se llama el ciclo.
19 ;
20 ;Introducción de parámetros
21 FN 0: Q1 =+46 ;SEMIEJE DE LA ELIPSE EN EL EJE X
22 FN 0: Q2 =+20 ;SEMIEJE DE LA ELIPSE EN EL EJE Y
23 FN 0: Q5 =+0.5 ;PASO ANGULAR
24 FN 0: Q6 =+15 ;ROTACIÓN DE LA ELIPSE
25 FN 0: Q8 =+50 ;CENTRO DE LA ELIPSE EN EL EJE X
26 FN 0: Q9 =+40 ;CENTRO DE LA ELIPSE EN EL EJE Y
27 FN 0: Q12 =+2 ;DISTANCIA DE SEGURIDAD
28 FN 0: Q13 =+30 ;NÚMERO DE MECANIZADOS
29 ;Fin de la introducción de parámetros
30 ;
31 BLK FORM 0.1 Z X+0 Y+0 Z-20
32 BLK FORM 0.2  X+100  Y+80  Z+0
33 ;
34 ;Llamada a la herramienta perforado NC
35 TOOL CALL 201 Z S1000
36 ;
37 ;Definición ciclo de mecanizado
38 CYCL DEF 1.0 TALADRADO PROFUNDO
39 CYCL DEF 1.1 DISTQ12
40 CYCL DEF 1.2 PROF-2.5
41 CYCL DEF 1.3 PASO10
42 CYCL DEF 1.4 T.ESPR0
43 CYCL DEF 1.5 F100
44 ;
45 CALL LBL 20 ;Llamada subprograma Posiciones
46 ;
47 ;Llamada de herramienta Broca
48 TOOL CALL 225 Z S1000
49 ;
50 ;Definición ciclo de mecanizado
51 CYCL DEF 1.0 TALADRADO PROFUNDO
52 CYCL DEF 1.1 DISTQ12
53 CYCL DEF 1.2 PROF-20
54 CYCL DEF 1.3 PASO10
55 CYCL DEF 1.4 T.ESPR0
56 CYCL DEF 1.5 F100
57 ;
58 CALL LBL 20 ;Llamada subprograma Posiciones
59 ;
60 ;Retirar la herramienta y final del programa
61 L  Z+100 R0 F9998 M30
62 ;
63 ;Subprograma para la determinación de las posiciones
64 LBL 20
65 ;Poner el punto cero en el centro de la elipse y establecer
66 ;la rotación
67 CYCL DEF 7.0 PUNTO CERO
68 CYCL DEF 7.1  X+Q8
69 CYCL DEF 7.2  Y+Q9
70 CYCL DEF 10.0 GIRO
71 CYCL DEF 10.1  ROT+Q6
72 CALL LBL 10 ;Llamada del cálculo de la elipse completa
73 FN 4: Q48 =+Q40 DIV +Q13
74 FN 0: Q50 =+Q40
75 FN 0: Q36 =+0 ;Resetear parámetros
76 FN 0: Q40 =+0 ;Resetear parámetros
77 FN 0: Q46 =+0 ;Resetear parámetros
78 FN 0: Q47 =+0 ;Resetear parámetros
79 FN 0: Q50 =+1 ;Contador
80 CALL LBL 2
81 L  X+Q21  Y+Q22 R0 F9999 M3 ;Ir a la primera posición
82 L  Z+Q12 M99 ;Ir a altura de seguridad y llamada del ciclo
83 LBL 21
84 FN 1: Q46 =+Q46 + +Q48
85 LBL 22
86 FN 1: Q36 =+Q36 + +Q5
87 CALL LBL 2
88 CALL LBL 3
89 FN 12: IF +Q47 LT +Q46 GOTO LBL 22
90 L  X+Q21  Y+Q22 M99 ;Ir a posición y llamada al ciclo
91 FN 1: Q50 =+Q50 + +1 ;Reanudar el recuento del contador
92 FN 12: IF +Q50 LT +Q13 GOTO LBL 21 ;Comparar el contador
93 ;Reponer punto cero y rotación
94 CYCL DEF 10.0 GIRO
95 CYCL DEF 10.1  ROT+0
96 CYCL DEF 7.0 PUNTO CERO
97 CYCL DEF 7.1  X+0
98 CYCL DEF 7.2  Y+0
99 LBL 0
100 ;
101 ;Cálculo de la elipse
102 LBL 10
103 FN 0: Q40 =+0
104 FN 0: Q36 =+0 ;Ángulo inicial
105 FN 0: Q4 =+360 ;Ángulo final
106 CALL LBL 2
107 LBL 1
108 FN 1: Q36 =+Q36 + +Q5 ;Continuación de recuento del ángulo
109 CALL LBL 2
110 CALL LBL 3
111 FN 12: IF +Q36 LT +Q4 GOTO LBL 1 ;Comparación entre el ángulo actual y el ángulo final
112 FN 0: Q36 =+Q4
113 CALL LBL 2
114 LBL 0
115 LBL 2 ;Cálculo de coordenadas
116 FN 7: Q21 = COS +Q36
117 FN 3: Q21 =+Q21 * +Q1
118 FN 6: Q22 = SIN +Q36
119 FN 3: Q22 =+Q22 * +Q2
120 LBL 0
121 LBL 3 ;Calcular el ángulo y coordenadas
122 FN 1: Q37 =+Q36 + +Q5
123 FN 7: Q31 = COS +Q37
124 FN 3: Q31 =+Q31 * +Q1
125 FN 6: Q32 = SIN +Q37
126 FN 3: Q32 =+Q32 * +Q2
127 FN 2: Q34 =+Q31 - +Q21
128 FN 2: Q35 =+Q32 - +Q22
129 FN 8: Q39 =+Q35 LEN +Q34
130 FN 1: Q40 =+Q40 + +Q39
131 FN 1: Q47 =+Q40 + +0
132 LBL 0
133 END PGM 1010_ES MM