0 BEGIN PGM 1065_ES MM 
1 ;Programa para centrar en diferentes posiciones, crear
2 ;un taladro piloto, y luego taladrar éste más profundo.
3 ;Las posiciones y otros parámetros del taladrado están
4 ;guardadas en una tabla.
5 ;
6 BLK FORM 0.1 Z X+0 Y+0 Z-100
7 BLK FORM 0.2  X+100  Y+100  Z+0
8 ;
9 ;Definir tabla con parámetros de taladrado
10 FN 26: TABOPEN 10651_es.tab
11 ;
12 ;Llamada de herramienta Broca de centrado
13 TOOL CALL 203 Z S2000
14 ;
15 CYCL DEF 203 TALAD. UNIVERSAL ~
   Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q201=-3    ;PROFUNDIDAD ~
    Q206=+150  ;AVANCE PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q210=+0    ;TIEMPO ESPERA ARRIBA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q212=+0    ;VALOR DECREMENTO ~
    Q213=+0    ;NUMERO ROTURA VIRUTA ~
    Q205=+0    ;PASO PROF. MINIMO ~
    Q211=+0    ;TIEMPO ESPERA ABAJO ~
    Q208=+30000 ;AVANCE SALIDA ~
    Q256=+0.2  ;DIST RETIR ROT VIRUT
16 ;
17 ;Definir las líneas de la tabla a emplear
18 FN 0: Q51 =+0 ;LÍNEA DE INICIO
19 FN 0: Q52 =+4 ;OTRAS LÍNEAS
20 ;
21 CALL LBL 12
22 ;
23 STOP
24 ;
25 ;Llamada a la herramienta broca para taladrado piloto
26 TOOL CALL 227 Z S2000
27 ;
28 ;Definir los parámetros a modificar del ciclo de taladrado
29 FN 0: Q201 =-10 ;Nueva profundidad
30 ;
31 CALL LBL 12
32 ;
33 STOP
34 ;
35 ;Llamada a la herramienta para el taladro profundo
36 TOOL CALL 226 Z
37 ;
38 ;Definición de parámetros para el taladro profundo
39 FN 0: Q1 =+0 ;Borde superior
40 FN 0: Q2 =+0 ;Profundidad del pretaladrado
41 FN 0: Q3 =-10 ;Altura de extracción de viruta
42 FN 0: Q4 =+1000 ;Avance hasta la entrada
43 FN 0: Q5 =+200 ;Avance hasta el taladrado
44 FN 0: Q6 =+2000 ;Velocidad de rotación
45 FN 0: Q7 =+5 ;Ajuste
46 FN 0: Q8 =+0 ;Profundidad
47 FN 0: Q9 =+0.5 ;Tiempo de espera
48 FN 0: Q10 =+1 ;Valor de rotura de viruta
49 FN 0: Q11 =+2 ;Valor de seguridad 1 (incremental)
50 FN 0: Q12 =+30 ;Valor de seguridad 2 (incremental)
51 FN 0: Q13 =+5 ;Número de aproximaciones
52 ;
53 ;Definir PGM 10652_es.h como ciclo
54 CYCL DEF 12.0 PGM CALL
55 CYCL DEF 12.1 PGM 10652_es.h
56 ;
57 CALL LBL 12
58 ;
59 ;Retirar la herramienta y final del programa
60 L  X+0  Y+0  Z+100 FMAX M2
61 ;
62 ;Desplazamiento a posiciones
63 LBL 12
Q61 = Q51 ;Definir la línea de la tabla de la primera posición
64 LBL 11
65 CALL LBL 10
66 FN 1: Q61 =+Q61 + +1 ;Continuar cálculo de la línea de la tabla
67 CALL LBL 11 REPQ52
68 LBL 0
69 ;
70 ;Instrucción de lectura, hacer aproximación a la posición y llamar ciclo
71 LBL 10
72 FN 28: TABREAD Q41 =Q61 /"X"
73 FN 28: TABREAD Q42 =Q61 /"Y"
74 FN 28: TABREAD Q1 =Q61 /"Z"
75 FN 28: TABREAD Q8 =Q61 /"Depth"
76 FN 28: TABREAD Q45 =Q61 /"Distance"
77 FN 28: TABREAD Q46 =Q61 /"Feed_rate"
78 FN 28: TABREAD Q47 =Q61 /"Safe_height"
79 L  X+Q41  Y+Q42 R0 FMAX M13 M99
80 LBL 0
81 END PGM 1065_ES MM