0 BEGIN PGM 1105_ES MM 
1 ;Programa para la definición de un patrón de puntos en
2 ;forma de marco.
3 ;Para el mecanizado se llama un ciclo de mecanizado en
4 ;las posiciones calculadas. En este programa un ciclo de
5 ;taladrado. Tras la definición de todos los parámetros que
6 ;se precisan, de la herramienta y del ciclo de mecanizado,
7 ;se llama un subprograma en el que se calculan las
8 ;posiciones individuales y se hace la aproximación a las
9 ;mismas, y se ejecuta el ciclo.
10 ;
11 ;Introducción de parámetros
12 FN 0: Q1 =+15 ;POSICIÓN INICIAL EN EL EJE X
13 FN 0: Q2 =+15 ;POSICIÓN INICIAL EN EL EJE Y
14 FN 0: Q30 =+8 ;NÚMERO DE MECANIZADOS EN X
15 FN 0: Q31 =+8 ;NÚMERO DE MECANIZADOS EN Y
16 FN 0: Q32 =+10 ;DISTANCIA DE LOS MECANIZADOS EN X
17 FN 0: Q33 =+10 ;DISTANCIA DE LOS MECANIZADOS EN Y
18 FN 0: Q7 =+0 ;ROTACIÓN
19 FN 0: Q8 =+2 ;DISTANCIA DE SEGURIDAD
20 ;Fin de la introducción de parámetros
21 ;
22 BLK FORM 0.1 Z X+0 Y+0 Z-25
23 BLK FORM 0.2  X+100  Y+100  Z+0
24 ;
25 ;Llamada de herramienta Broca
26 TOOL CALL 225 Z S5000
27 ;
28 ;Definición ciclo de mecanizado
29 CYCL DEF 1.0 TALADRADO PROFUNDO
30 CYCL DEF 1.1 DISTQ8
31 CYCL DEF 1.2 PROF-20
32 CYCL DEF 1.3 PASO10
33 CYCL DEF 1.4 T.ESPR0
34 CYCL DEF 1.5 F100
35 ;
36 CALL LBL 20 ;Llamada subprograma Posiciones
37 ;
38 ;Retirar la herramienta y final del programa
39 L  Z+100 R0 FMAX M2
40 ;
41 LBL 20 ;Definición de las posiciones
42 FN 12: IF +Q30 LT +3 GOTO LBL 5
43 FN 12: IF +Q31 LT +3 GOTO LBL 5
44 ;Desplazar el punto cero a la primera posición
45 CYCL DEF 7.0 PUNTO CERO
46 CYCL DEF 7.1  X+Q1
47 CYCL DEF 7.2  Y+Q2
48 ;Establecer rotación
49 CYCL DEF 10.0 GIRO
50 CYCL DEF 10.1  ROT+Q7
51 ;
52 L  Z+100 R0 FMAX ;Desplazarse a altura de seguridad
53 L  X+0  Y+0 R0 FMAX M3 ;Desplazarse a la primera posición
54 L  Z+Q8 R0 FMAX M99 ;Desplazarse a la distancia de seguridad y llamar el ciclo
55 FN 2: Q34 =+Q30 - +1 ;Contador columnas
56 LBL 1
57 FN 2: Q34 =+Q34 - +1 ;Contador columnas
58 L IX+Q32 FMAX M99 ;Ir a la posición siguiente y llamar ciclo
59 FN 11: IF +Q34 GT +0 GOTO LBL 1 ;Comparar si otras columnas
60 FN 2: Q35 =+Q31 - +1 ;Contador líneas
61 LBL 2
62 FN 2: Q35 =+Q35 - +1 ;Contador líneas
63 L IY+Q33 FMAX M99 ;Hacer la aproximación a la siguiente posición y llamar ciclo
64 FN 11: IF +Q35 GT +0 GOTO LBL 2 ;Comparar si son necesarias otras líneas
65 FN 2: Q34 =+Q30 - +1 ;Contador columnas
66 LBL 3
67 FN 2: Q34 =+Q34 - +1 ;Contador columnas
68 L IX-Q32 FMAX M99 ;Hacer la aproximación a la siguiente posición y llamar ciclo
69 FN 11: IF +Q34 GT +0 GOTO LBL 3 ;Comparar si son necesarias otras columnas
70 FN 2: Q36 =+Q31 - +2 ;Contador líneas
71 LBL 4
72 FN 2: Q36 =+Q36 - +1 ;Contador líneas
73 L IY-Q33 FMAX M99 ;Hacer la aproximación a la siguiente posición y llamar ciclo
74 FN 11: IF +Q36 GT +0 GOTO LBL 4 ;Comparar si son necesarias otras líneas
75 FN 9: IF +0 EQU +0 GOTO LBL 6 ;Salto al final del subprograma
76 LBL 5
77 FN 14: ERROR= 1011
78 LBL 6
79 ;Reponer punto cero y rotación
80 CYCL DEF 7.0 PUNTO CERO
81 CYCL DEF 7.1  X+0
82 CYCL DEF 7.2  Y+0
83 CYCL DEF 7.3  Z+0
84 CYCL DEF 10.0 GIRO
85 CYCL DEF 10.1  ROT+0
86 LBL 0
87 END PGM 1105_ES MM