0 BEGIN PGM 1110_ES MM 
1 ;Programa para la definición de un patrón de puntos en
2 ;forma de círculo. En este ejemplo combinado con un
3 ;segundo programa, en el que se crean taladros mediante
4 ;fresados de taladro, estando programados en dicho
5 ;programa los movimientos helicoidales y no se emplea
6 ;ningún ciclo.
7 ;Tras la definición de todos los parámetros necesarios y
8 ;de la herramienta se define el ciclo de mecanizado.
9 ;En este ejemplo, con el ciclo 12 se llama el segundo
10 ;programa. A continuación se hace la aproximación a las
11 ;posiciones individuales, y se llama el ciclo.
12 ;
13 ;Introducción de parámetros Círculo de taladros
14 FN 0: Q31 =+40 ;RADIO DEL CÍRCULO DE TALADROS
15 FN 0: Q32 =+0 ;ANGULO INICIAL
16 FN 0: Q33 =+50 ;CENTRO CÍRCULO DE TALADROS EN EL EJE X
17 FN 0: Q34 =+50 ;CENTRO CÍRCULO DE TALADROS EN EL EJE Y
18 FN 0: Q35 =+30 ;PASO ANGULAR
19 FN 0: Q36 =+12 ;NÚMERO DE MECANIZADOS
20 ;Introducción de parámetros Círculo de taladros Final
21 ;Introducción de parámetros Taladros
22 FN 0: Q40 =+10 ;DIÁMETRO DEL TALADRO
23 FN 0: Q41 =-30 ;PROFUNDIDAD
24 FN 0: Q42 =+25 ;NÚMERO DE TRAYECTORIAS HELICOIDALES
25 FN 0: Q43 =+2 ;DISTANCIA DE SEGURIDAD
26 FN 0: Q44 =+1200 ;AVANCE DE FRESADO
27 ;Introducción de parámetros Taladros Final
28 ;
29 ;Cálculos
30 ;Círculo de taladros
31 FN 2: Q37 =+Q36 - +2 ;Número de repeticiones
32 ;Taladros
33 FN 4: Q45 =+Q40 DIV +2 ;Radio del taladro
34 FN 3: Q46 =+Q42 * +360 ;Ángulo de la trayectoria helicoidal
35 ;Fin de los cálculos
36 ;
37 BLK FORM 0.1 Z X+0 Y+0 Z-40
38 BLK FORM 0.2  X+100  Y+100  Z+0
39 ;
40 ;Llamada de herramienta de fresado
41 TOOL CALL 4 Z S8000
42 ;
43 ;Retirar la hta.
44 L  Z+100 R0 FMAX M3
45 ;
46 ;Definición del programa 11101_es.h como ciclo
47 CYCL DEF 12.0 PGM CALL
48 CYCL DEF 12.1 PGM 11101_es.h
49 ;
50 CALL LBL 1 ;Llamada posiciones
51 ;
52 ;Retirar la herramienta y final del programa
53 L  Z+50 R0 F9999 M2
54 ;
55 ;Subprograma posiciones
56 LBL 1
57 CC  X+Q33  Y+Q34 ;Centro del círculo de taladros
58 LP  PR+Q31  PA+Q32 R0 F9999 ;Primera posición
59 CYCL CALL
60 LBL 2
61 CC  X+Q33  Y+Q34 ;Coordenada punto central
62 LP IPA+Q35 F9999 M99 ;Paso angular
63 CALL LBL 2 REPQ37
64 LBL 0
65 END PGM 1110_ES MM