0 BEGIN PGM 2130_ES MM 
1 ;Programa para crear una cajera con el contorno de perfil de
2 ;polígono P3G según DIN 32711.
3 BLK FORM 0.1 Z X+0 Y+0 Z-25
4 BLK FORM 0.2  X+100  Y+100  Z+0
5 ;
6 ;Llamada de herramienta fresa de mango D20
7 TOOL CALL 13 Z S5000
8 ;
9 ;Datos de corte
Q50 = 20 ;PROF. DE FRESADO
Q51 = 3 ;PROFUNDIDAD DE APROXIMACIÓN
Q52 = 2 ;DISTANCIA DE SEGURIDAD
Q53 = 150 ;AVANCE AL PROFUNDIZAR
Q54 = 500 ;AVANCE DE FRESADO
10 ;
11 ;Parámetro para polígono P3G
Q30 = 75 ;DIÁMETRO DE LA CURVA DE ANCHO CONSTANTE (D1)
Q31 = 3.15 ;TAMAÑO DE LA EXCÉNTRICA (E)
Q36 = 50 ;CENTRO DEL POLÍGONO EN EL EJE X
Q37 = 50 ;CENTRO DEL POLÍGONO EN EL EJE Y
Q38 = 0 ;ROTACIÓN
12 ;Fin de la introducción de parámetros
13 ;===========================================
Q35 = 0 ;INICIO PARA EL ÁNGULO INCREMENTAL
14 CYCL DEF 7.0 PUNTO CERO
15 CYCL DEF 7.1  X+Q36
16 CYCL DEF 7.2  Y+Q37
17 CYCL DEF 10.0 GIRO
18 CYCL DEF 10.1  ROT+Q38
19 CYCL DEF 14.0 CONTORNO
20 CYCL DEF 14.1 LABEL CONTORNO1
21 CYCL DEF 20 DATOS DEL CONTORNO ~
   Q1=-Q50  ;PROFUNDIDAD FRESADO ~
    Q2=+1    ;SOLAPAM. TRAYECTORIA ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q4=+0    ;SOBREMEDIDA PROFUND. ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q6=+Q52  ;DISTANCIA SEGURIDAD ~
    Q7=+50   ;ALTURA DE SEGURIDAD ~
    Q8=+0    ;RADIO DE REDONDEO ~
    Q9=+1    ;SENTIDO DE GIRO
22 CYCL DEF 22 DESBASTE ~
   Q10=-Q51  ;PASO PROFUNDIZACION ~
    Q11=+Q53  ;AVANCE PROFUNDIDAD ~
    Q12=+Q54  ;AVANCE PARA DESBASTE ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q19=+0    ;AVANCE OSCILACION ~
    Q208=+99999 ;AVANCE SALIDA
23 L  X+0  Y+0 R0 FMAX M3 M99
24 CYCL DEF 10.0 GIRO
25 CYCL DEF 10.1  ROT+0
26 CYCL DEF 7.0 PUNTO CERO
27 CYCL DEF 7.1  X+0
28 CYCL DEF 7.2  Y+0
29 ;
30 ;Final del programa
31 L  Z+50 R0 FMAX M30
32 ;
33 ;Subprograma
34 ;Cálculo de los puntos del contorno
35 LBL 1
Q40 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * COS Q35 - 3 * Q31 * SIN ( 3 * Q35 ) * SIN Q35
Q41 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * SIN Q35 + 3 * Q31 * SIN ( 3 * Q35 ) * COS Q35
36 L  X+Q40  Y+Q41 RL
Q35 = Q35 + 0.5
37 FN 10: IF +Q35 NE +360.5 GOTO LBL 1
38 LBL 0
39 END PGM 2130_ES MM