0 BEGIN PGM 2140_ES MM 
1 ;Programa para crear una isla con el contorno de perfil de
2 ;un perfil de polígono P4C según DIN 32712.
3 BLK FORM 0.1 Z X+0 Y+0 Z-25
4 BLK FORM 0.2  X+100  Y+100  Z+0
5 ;
6 ;Llamada de herramienta fresa de mango D20
7 TOOL CALL 13 Z S5000
8 ;
9 ;Datos de corte
Q50 = 20 ;PROF. DE FRESADO
Q51 = 3 ;PROFUNDIDAD DE APROXIMACIÓN
Q52 = 2 ;DISTANCIA DE SEGURIDAD
Q53 = 150 ;AVANCE AL PROFUNDIZAR
Q54 = 500 ;AVANCE DE FRESADO
10 ;
11 ;Parámetro para polígono P4C
Q28 = 141 ;DIÁMETRO DE LA PIEZA EN BRUTO
Q29 = 75 ;DIÁMETRO DEL CÍRCULO EXTERIOR (d1)
Q30 = 65 ;DIÁMETRO DEL CÍRCULO INTERIOR (d2)
Q31 = 6 ;TAMAÑO DE LA EXCÉNTRICA (e)
Q36 = 50 ;CENTRO DEL POLÍGONO EN EL EJE X
Q37 = 50 ;CENTRO DEL POLÍGONO EN EL EJE Y
Q38 = 0 ;ROTACIÓN
12 ;
13 ;===========================================
14 CYCL DEF 7.0 PUNTO CERO
15 CYCL DEF 7.1  X+Q36
16 CYCL DEF 7.2  Y+Q37
17 CYCL DEF 10.0 GIRO
18 CYCL DEF 10.1  ROT+Q38
19 ;
20 ;prefabricar el eje
21 CYCL DEF 257 ISLA CIRCULAR ~
   Q223=+Q29  ;DIAMETRO TERMINADO ~
    Q222=+Q28  ;DIAMETRO BRUTO ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q207=+Q54  ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-Q50  ;PROFUNDIDAD ~
    Q202=+Q51  ;PASO PROFUNDIZACION ~
    Q206=+Q53  ;AVANCE PROFUNDIDAD ~
    Q200=+Q52  ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q370=+1    ;SOLAPAM. TRAYECTORIA ~
    Q376=-1    ;ANGULO INICIAL
22 L  X+0  Y+0 R0 FMAX M3 M99
23 ;
24 ;fresar el perfil P4C
25 CYCL DEF 14.0 CONTORNO
26 CYCL DEF 14.1 LABEL CONTORNO1
27 CYCL DEF 25 TRAZADO CONTORNO ~
   Q1=-Q50  ;PROFUNDIDAD FRESADO ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q7=+Q52  ;ALTURA DE SEGURIDAD ~
    Q10=-Q51  ;PASO PROFUNDIZACION ~
    Q11=+Q53  ;AVANCE PROFUNDIDAD ~
    Q12=+Q54  ;AVANCE PARA DESBASTE ~
    Q15=+1    ;TIPO DE FRESADO
28 L M99
29 CYCL DEF 10.0 GIRO
30 CYCL DEF 10.1 IROT-90
31 L M99
32 CYCL DEF 10.0 GIRO
33 CYCL DEF 10.1 IROT-90
34 L M99
35 CYCL DEF 10.0 GIRO
36 CYCL DEF 10.1 IROT-90
37 L M99
38 ;
39 CYCL DEF 10.0 GIRO
40 CYCL DEF 10.1  ROT+0
41 CYCL DEF 7.0 PUNTO CERO
42 CYCL DEF 7.1  X+0
43 CYCL DEF 7.2  Y+0
44 ;
45 ;Final del programa
46 L  Z+100 R0 FMAX M30
47 ;
48 ;Subprograma
49 ;Cálculo de contorno
50 LBL 1
Q35 = - 26.5
51 LBL 2
Q41 = ( ( Q30 / 2 + Q31 ) - Q31 * COS ( 4 * Q35 ) ) * COS Q35 - 4 * Q31 * SIN ( 4 * Q35 ) * SIN Q35
Q42 = ( ( Q30 / 2 + Q31 ) - Q31 * COS ( 4 * Q35 ) ) * SIN Q35 + 4 * Q31 * SIN ( 4 * Q35 ) * COS Q35
52 L  X+Q41  Y+Q42 RR
Q35 = Q35 + 0.5
53 FN 10: IF +Q35 NE +27 GOTO LBL 2
54 LBL 0
55 END PGM 2140_ES MM