0 BEGIN PGM 2145_ES MM 
1 ;Programa NC en el que está definido un ciclo SL
2 ;La particularidad es que mediante un parámetro
3 ;Q se puede seleccionar cual número de subprograma
4 ;se debe emplear como contorno. Para ello se define
5 ;como inicio del programa un parámetro con el
6 ;número del subprograma a emplear, en el ejemplo
7 ;11 o 12. En el ciclo 14 se da entonces el número
8 ;de subprograma de la isla y el de otro subprograma.
9 ;Dicho segundo subprograma se componen únicamente
10 ;de un CALL LBL con el parámetro Q definido al
11 ;principio, de tal manera que se emplee el programa
12 ;seleccionado.
13 ;
14 BLK FORM 0.1 Z X+200 Y-50 Z-10
15 BLK FORM 0.2  X+300  Y+50  Z+30
16 ;
17 ;Llamada a la herramienta
18 TOOL CALL 4 Z S8000
19 ;
20 L  Z+100 R0 F9999 M3 ;Retirar la hta.
21 ;
22 FN 0: Q30 =+12 ;SELECCIÓN DEL CONTORNO DE LA CAJERA
23 ;
24 ;Definición de la etiqueta de contorno
25 CYCL DEF 14.0 CONTORNO
26 CYCL DEF 14.1 LABEL CONTORNO10 /2
27 ;
28 ;Ciclos de mecanizado
29 CYCL DEF 20 DATOS DEL CONTORNO ~
   Q1=-34   ;PROFUNDIDAD FRESADO ~
    Q2=+1    ;SOLAPAM. TRAYECTORIA ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q4=+0    ;SOBREMEDIDA PROFUND. ~
    Q5=+30   ;COORD. SUPERFICIE ~
    Q6=+2    ;DISTANCIA SEGURIDAD ~
    Q7=+5    ;ALTURA DE SEGURIDAD ~
    Q8=+0    ;RADIO DE REDONDEO ~
    Q9=+1    ;SENTIDO DE GIRO
30 CYCL DEF 22 DESBASTE ~
   Q10=-4    ;PASO PROFUNDIZACION ~
    Q11=+300  ;AVANCE PROFUNDIDAD ~
    Q12=+1500 ;AVANCE PARA DESBASTE ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q19=+500  ;AVANCE OSCILACION ~
    Q208=+99999 ;AVANCE SALIDA ~
    Q401=+70   ;FACTOR DE AVANCE ~
    Q404=+0    ;ESTRATEGIA PROFUND.
31 CYCL CALL M3
32 L  Z+100 R0 F99999 ;Retirar la hta.
33 M30 ;Final del programa
34 ;
35 ;Subprogramas
36 ;
37 LBL 2 ;Contorno de la isla
38 L  X+200  Y+26 RL
39 L  X+300  Y+36
40 L  Y-36
41 L  X+200  Y-26
42 L  X+200  Y+26
43 LBL 0
44 ;
45 LBL 10 ;Subprograma selección cajera
46 CALL LBL Q30
47 LBL 0
48 ;
49 LBL 11 ;Contorno cajera 1
50 L  X+194  Y-56 RR
51 L  Y+46
52 L  X+306
53 L  Y-46
54 L  X+194
55 LBL 0
56 ;
57 LBL 12 ;Contorno cajera 2
58 L  X+194  Y-56 RR
59 L  Y+56
60 L  X+306
61 L  Y-56
62 L  X+194
63 LBL 0
64 END PGM 2145_ES MM