0 BEGIN PGM 3040_ES MM 
1 ;Programa para mecanizar desde la parte exterior un
2 ;cono truncado recostado. El eje de rotación transcurre
3 ;paralelamente al eje X. El mecanizado se realiza con
4 ;una fresa esférica en líneas del contorno, cuyo número
5 ;se define con el parámetro División (Q8).
6 ;
7 ;Introducción de parámetros
8 FN 0: Q13 =+30 ;CENTRO DEL CONO EN Y
9 FN 0: Q14 =-35 ;CENTRO DEL CONO EN Z
10 FN 0: Q1 =+0 ;COORDENADA X MÍNIMA
11 FN 0: Q5 =+100 ;COORDENADA X MÁXIMA
12 FN 0: Q6 =+30 ;RADIO EN X MÍNIMA
13 FN 0: Q7 =+20 ;RADIO EN X MÁXIMA
14 FN 0: Q8 =+90 ;DIVISIÓN
15 FN 0: Q10 =+30 ;DISTANCIA DE SEGURIDAD
16 FN 0: Q11 =+300 ;AVANCE AL PROFUNDIZAR
17 FN 0: Q12 =+1000 ;AVANCE DE FRESADO
18 ;Fin de la introducción de parámetros
19 ;
20 BLK FORM 0.1 Z X+0 Y+0 Z-35
21 BLK FORM 0.2  X+100  Y+60  Z+0
22 ;
23 ;Llamada a la herramienta fresa esférica
24 TOOL CALL 157 Z S4000
25 TOOL CALL  Z DL-Q108 ;Corrección de la longitud al centro de la esfera
26 ;
27 L  X-20  Y+0  Z+28 R0 F5555 ;Posicionamiento previo
28 ;
29 CALL LBL 1 ;Llamada al mecanizado
30 ;
31 ;Resetear conversión de coordenadas
32 CYCL DEF 7.0 PUNTO CERO
33 CYCL DEF 7.1  X+0
34 CYCL DEF 7.2  Y+0
35 CYCL DEF 7.3  Z+0
36 ;
37 ;Retirar la herramienta y final del programa
38 L  Z+100 R0 FMAX M2
39 ;
40 LBL 1 ;Mecanizado
41 ;Cálculos
42 FN 1: Q16 =+Q6 + +Q108 ;Radio hasta el centro de la herramienta con X mín
43 FN 1: Q17 =+Q7 + +Q108 ;Radio hasta el centro de la herramienta con X máx
44 FN 0: Q27 =+0 ;Ángulo inicial
Q37 = 180 / Q8 ;Paso angular
45 FN 0: Q28 =+0 ;Contador
46 ;
47 ;Desplazar el punto cero al centro de la esfera
48 CYCL DEF 7.0 PUNTO CERO
49 CYCL DEF 7.1  Y+Q13
50 CYCL DEF 7.2  Z+Q14
51 ;
52 CALL LBL 10
53 L  X+Q1  Y+Q22 R0 F5555 ;Aproximación al punto inicial
54 L  Z+Q23 FQ11 ;Profundización
55 L  X+Q5  Y+Q42  Z+Q43 ;Ir al punto final
56 L IZ+Q10 ;Desplazarse a la distancia de seguridad
57 ;
58 LBL 2
Q27 = Q27 + Q37 ;Continuación de recuento del ángulo
Q28 = Q28 + 1 ;Continuación del recuento del contador
59 FN 11: IF +Q28 GT +Q8 GOTO LBL 99
60 CALL LBL 10
61 L  X+Q1  Y+Q22 R0 F5555 ;Aproximación al punto inicial
62 L  Z+Q23 FQ11 ;Profundización
63 L  X+Q5  Y+Q42  Z+Q43 ;Ir al punto final
64 L IZ+Q10 ;Desplazarse a la distancia de seguridad
65 FN 9: IF +0 EQU +0 GOTO LBL 2 ;Repetición
66 ;
67 LBL 10 ;Cálculo de las coordenadas
Q22 = Q16 * COS Q27 ;Coordenada Y, X mín
Q42 = Q17 * COS Q27 ;Coordenada Y, X máx
Q23 = Q16 * SIN Q27 ;Coordenada Z, X mín
Q43 = Q17 * SIN Q27 ;Coordenada Z, X máx
68 LBL 0
69 LBL 99 ;Final del mecanizado
70 LBL 0
71 END PGM 3040_ES MM