0 BEGIN PGM 3045_ES MM 
1 ;Programa para mecanizar desde la parte interior
2 ;un cono truncado recostado. El eje de rotación
3 ;transcurre paralelamente al eje X. El mecanizado
4 ;se realiza con una fresa esférica en líneas del
5 ;contorno, cuyo número se define con el parámetro
6 ;División (Q8).
7 ;
8 ;Introducción de parámetros
9 FN 0: Q13 =+35 ;CENTRO DEL CONO EN Y
10 FN 0: Q14 =+0 ;CENTRO DEL CONO EN Z
11 FN 0: Q1 =+0 ;COORDENADA X MÍNIMA
12 FN 0: Q5 =+100 ;COORDENADA X MÁXIMA
13 FN 0: Q6 =+30 ;RADIO EN X MÍNIMA
14 FN 0: Q7 =+20 ;RADIO EN X MÁXIMA
15 FN 0: Q8 =+90 ;DIVISIÓN
16 FN 0: Q10 =+30 ;DISTANCIA DE SEGURIDAD
17 FN 0: Q11 =+300 ;AVANCE AL PROFUNDIZAR
18 FN 0: Q12 =+1000 ;AVANCE DE FRESADO
19 ;Fin de la introducción de parámetros
20 ;
21 BLK FORM 0.1 Z X+0 Y+0 Z-35
22 BLK FORM 0.2  X+100  Y+70  Z+0
23 ;
24 ;Llamada a la herramienta fresa esférica
25 TOOL CALL 157 Z S4000
26 TOOL CALL  Z DL-Q108 ;Corrección de la longitud al centro de la esfera
27 ;
28 L  X-20  Y+0  Z+28 R0 F5555 ;Posicionamiento previo
29 ;
30 CALL LBL 1 ;Llamada al mecanizado
31 ;
32 ;Resetear conversión de coordenadas
33 CYCL DEF 7.0 PUNTO CERO
34 CYCL DEF 7.1  X+0
35 CYCL DEF 7.2  Y+0
36 CYCL DEF 7.3  Z+0
37 ;
38 ;Retirar la herramienta y final del programa
39 L  Z+100 R0 FMAX M2
40 ;
41 LBL 1 ;Mecanizado
42 ;Cálculos
43 FN 2: Q16 =+Q6 - +Q108 ;Radio hasta el centro de la herramienta con X mín
44 FN 2: Q17 =+Q7 - +Q108 ;Radio hasta el centro de la herramienta con X máx
45 FN 0: Q27 =+180 ;Ángulo inicial
Q37 = 180 / Q8 ;Paso angular
46 FN 0: Q28 =+0 ;Contador
47 ;
48 ;Desplazar el punto cero al centro de la esfera
49 CYCL DEF 7.0 PUNTO CERO
50 CYCL DEF 7.1  Y+Q13
51 CYCL DEF 7.2  Z+Q14
52 ;
53 CALL LBL 10
54 L  X+Q1  Y+Q22 R0 F5555 ;Aproximación al punto inicial
55 L  Z+Q23 FQ11 ;Profundización
56 L  X+Q5  Y+Q42  Z+Q43 ;Ir al punto final
57 L IZ+Q10 ;Desplazarse a la distancia de seguridad
58 ;
59 LBL 2
Q27 = Q27 + Q37 ;Continuación de recuento del ángulo
Q28 = Q28 + 1 ;Continuación del recuento del contador
60 FN 11: IF +Q28 GT +Q8 GOTO LBL 99
61 CALL LBL 10
62 L  X+Q1  Y+Q22 R0 F5555 ;Aproximación al punto inicial
63 L  Z+Q23 FQ11 ;Profundización
64 L  X+Q5  Y+Q42  Z+Q43 ;Ir al punto final
65 L IZ+Q10 ;Desplazarse a la distancia de seguridad
66 FN 9: IF +0 EQU +0 GOTO LBL 2 ;Repetición
67 ;
68 LBL 10 ;Cálculo de las coordenadas
Q22 = Q16 * COS Q27 ;Coordenada Y, X mín
Q42 = Q17 * COS Q27 ;Coordenada Y, X máx
Q23 = Q16 * SIN Q27 ;Coordenada Z, X mín
Q43 = Q17 * SIN Q27 ;Coordenada Z, X máx
69 LBL 0
70 LBL 99 ;Final del mecanizado
71 LBL 0
72 END PGM 3045_ES MM