0 BEGIN PGM 3120_ES MM 
1 ;Programa para fresar un contorno y, a continuación,
2 ;redondear un radio en el borde superior. En el ejemplo
3 ;se programa un contorno como isla. Después de haberse
4 ;definido los parámetros necesarios, el control numérico
5 ;desbasta el contorno. Luego calcula las modificaciones del
6 ;contorno conforme a la profundidad correspondiente. Ésta
7 ;la emplea entonces el control numérico como sobremedida
8 ;lateral en el ciclo, para planear el radio en líneas de
9 ;contorno.
10 ;
11 BLK FORM 0.1 Z X+0 Y+0 Z-20
12 BLK FORM 0.2  X+100  Y+100  Z+0
13 ;
14 ;Introducción de parámetros
15 FN 0: Q31 =+15 ;PROFUNDIDAD CONTORNO
16 FN 0: Q32 =+5 ;PROFUNDIDAD DE APROXIMACIÓN FRESADO DEL CONTORNO
17 FN 0: Q33 =+1200 ;AVANCE FRESADO DEL CONTORNO
18 FN 0: Q34 =+300 ;AVANCE AL PROFUNDIZAR
19 FN 0: Q41 =+8 ;RADIO DE REDONDEO
20 FN 0: Q42 =+0.1 ;PROFUNDIDAD DE APROXIMACIÓN PLANEADO DEL RADIO
21 FN 0: Q48 =+3000 ;AVANCE FRESADO RADIO
22 ;Fin de la introducción de parámetros
23 ;
24 ;Llamada de herramienta fresa cilíndrica
25 TOOL CALL 13 Z S1000
26 ;
27 ;Ir a altura de seguridad
28 L  Z+100 R0 FMAX M3
29 ;
30 ;Contorno fresa
31 CYCL DEF 14.0 CONTORNO
32 CYCL DEF 14.1 LABEL CONTORNO1 /2
33 CYCL DEF 20 DATOS DEL CONTORNO ~
   Q1=-Q31  ;PROFUNDIDAD FRESADO ~
    Q2=+1    ;SOLAPAM. TRAYECTORIA ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q4=+0    ;SOBREMEDIDA PROFUND. ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q6=+0    ;DISTANCIA SEGURIDAD ~
    Q7=+0    ;ALTURA DE SEGURIDAD ~
    Q8=+0    ;RADIO DE REDONDEO ~
    Q9=+1    ;SENTIDO DE GIRO
34 CYCL DEF 22 DESBASTE ~
   Q10=-Q32  ;PASO PROFUNDIZACION ~
    Q11=+Q34  ;AVANCE PROFUNDIDAD ~
    Q12=+Q33  ;AVANCE PARA DESBASTE ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q19=+Q33  ;AVANCE OSCILACION
35 CYCL CALL M13
36 ;
37 ;Planear radio
38 FN 0: Q44 =+Q42
39 LBL 3
40 ;Cálculos de la variación del contorno con nueva profundidad
Q43 = Q41 * Q41
Q45 = Q41 - Q42
41 FN 3: Q45 =+Q45 * +Q45
Q43 = Q43 - Q45
Q43 = SQRT Q43
42 FN 2: Q50 =+Q41 - +Q43
43 ;Fin de los cálculos
44 ;Definición ciclo
45 CYCL DEF 14.0 CONTORNO
46 CYCL DEF 14.1 LABEL CONTORNO1
47 CYCL DEF 25 TRAZADO CONTORNO ~
   Q1=-Q42  ;PROFUNDIDAD FRESADO ~
    Q3=-Q50  ;SOBREMEDIDA LATERAL ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q7=+2    ;ALTURA DE SEGURIDAD ~
    Q10=-Q42  ;PASO PROFUNDIZACION ~
    Q11=+Q34  ;AVANCE PROFUNDIDAD ~
    Q12=+Q48  ;AVANCE PARA DESBASTE ~
    Q15=+1    ;TIPO DE FRESADO
48 CYCL CALL M13
49 ;
50 FN 1: Q42 =+Q42 + +Q44 ;Actualizar profundidad
51 ;Comparar si son necesarias otras trayectorias
52 FN 12: IF +Q42 LT +Q41 GOTO LBL 3
53 FN 9: IF +Q42 EQU +Q41 GOTO LBL 3
54 ;
55 ;Retirar la herramienta y final del programa
56 L  Z+100 R0 FMAX M30
57 ;
58 ;Subprogramas contornos
59 LBL 1 ;CONTORNO PGM
60 L  X+5  Y+30 RL
61 CC  X+15  Y+30
62 C  X+6.645  Y+35.495 DR-
63 CT  X+55.505  Y+69.488
64 CT  X+58.995  Y+30.025
65 CT  X+19.732  Y+21.191
66 CT  X+5  Y+30
67 LBL 0
68 ;
69 LBL 2 ;Marco PGM
70 L  X-30  Y-20 RR
71 L  Y+120
72 L  X+120
73 L  Y-20
74 L  X-30
75 LBL 0
76 END PGM 3120_ES MM