0 BEGIN PGM 3255_ES MM 
1 ;Programa NC para mecanizar un contorno con el
2 ;ciclo 25 y, a continuación, planear un bisel en
3 ;el borde superior.
4 ;El bisel lo planea el control numérico en líneas de
5 ;contorno. Para el cálculo de las líneas de contorno,
6 ;el control numérico lee el radio de la herramienta 2
7 ;de la tabla de herramientas. De este modo, el
8 ;mecanizado puede ejecutarse con una fresa de mango,
9 ;una fresa esférica o una fresa toroidal, sin
10 ;tener que modificar nada en el programa NC.
11 ;
12 BLK FORM 0.1 Z X+0 Y+0 Z-20
13 BLK FORM 0.2  X+100  Y+100  Z+0
14 ;
15 ;Llamada a la herramienta para el fresado del contorno
16 TOOL CALL "MILL_D24_ROUGH" Z S6000 F2000
17 ;
18 L  Z+100 R0 FMAX M3 ;Retirar la hta.
19 ;
20 CYCL DEF 14.0 CONTORNO
21 CYCL DEF 14.1 LABEL CONTORNO10
22 CYCL DEF 270 DATOS RECOR. CONTOR. ~
   Q390=+2    ;TIPO DE APROXIMACION ~
    Q391=+1    ;COMPENSACION RADIO ~
    Q392=+10   ;RADIO ~
    Q393=+90   ;ANGULO DEL CENTRO ~
    Q394=+0    ;DISTANCIA
23 CYCL DEF 25 TRAZADO CONTORNO ~
   Q1=-15   ;PROFUNDIDAD FRESADO ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q7=+50   ;ALTURA DE SEGURIDAD ~
    Q10=-5    ;PASO PROFUNDIZACION ~
    Q11=+150  ;AVANCE PROFUNDIDAD ~
    Q12=+500  ;AVANCE PARA DESBASTE ~
    Q15=+1    ;TIPO DE FRESADO ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q446=+0.01 ;MATERIAL RESTANTE ~
    Q447=+10   ;DISTANCIA DE UNION ~
    Q448=+2    ;PROLONG. TRAYECTORIA
24 M99 ;Llamada al ciclo
25 ;
26 ;Llamada a la herramienta para el fresado del bisel
27 TOOL CALL "BALL_MILL_D10" Z S6000 F2000
28 ;
29 L  Z+100 R0 FMAX M3
30 ;
31 ;Introducción de parámetros para el bisel
Q50 = 30 ;ÁNGULO DEL BISEL
Q51 = 0.2 ;DISTANCIA DE LAS LÍNEAS DE CONTORNO
Q52 = 2.5 ;LONGITUD DEL BISEL ARRIBA
32 CALL LBL "FASE" ;Llamada de subprograma para el fresado del bisel
33 ;
34 L  Z+100 R0 FMAX ;Retirar la hta.
35 M30 ;Final del programa
36 ;
37 ;Subprogramas
38 LBL 10 ;Contorno
39 L  X+10  Y+10
40 L  Y+90
41 CR  X+90  Y+90 R+100 DR+
42 L  Y+10
43 CR  X+10  Y+10 R+100 DR-
44 LBL 0
45 ;
46 ;Subprograma para el bisel
47 LBL "FASE"
48 CYCL DEF 14.0 CONTORNO
49 CYCL DEF 14.1 LABEL CONTORNO10
Q49 = Q108 + 2 ;Radio para aproximación suave
50 CYCL DEF 270 DATOS RECOR. CONTOR. ~
   Q390=+2    ;TIPO DE APROXIMACION ~
    Q391=+1    ;COMPENSACION RADIO ~
    Q392=+Q49  ;RADIO ~
    Q393=+90   ;ANGULO DEL CENTRO ~
    Q394=+0    ;DISTANCIA
51 FN 18: SYSREAD Q65 = ID50 NR3 ;Leer R2 de la herramienta activa
Q61 = 0 ;Comienzo Z
52 LBL 1
Q60 = Q52 / ( TAN Q50 ) ;Profundidad total Z
Q61 = Q61 + Q51 ;Calcular la coordenada Z de la nueva línea de contorno
53 FN 11: IF +Q61 GT +Q60 GOTO LBL "ENDE1" ;Comprobar si la nueva profundidad es mas grande que la profundidad total
54 FN 9: IF +Q61 EQU +Q60 GOTO LBL "ENDE1" ;Comprobar si la nueva profundidad es igual a la profundidad total
Q62 = Q61 + ( Q65 - SIN Q50 * Q65 ) ;Calcular la nueva coordenada Z teniendo en cuenta el radio de la herramienta R2
Q63 = ( Q52 - TAN Q50 * Q61 ) + ( Q65 - COS Q50 * Q65 ) ;Calcular la sobremedida para líneas de contorno
55 CYCL DEF 25 TRAZADO CONTORNO ~
   Q1=-Q62  ;PROFUNDIDAD FRESADO ~
    Q3=-Q63  ;SOBREMEDIDA LATERAL ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q7=+2    ;ALTURA DE SEGURIDAD ~
    Q10=-Q62  ;PASO PROFUNDIZACION ~
    Q11= AUTO ;AVANCE PROFUNDIDAD ~
    Q12= AUTO ;AVANCE PARA DESBASTE ~
    Q15=+1    ;TIPO DE FRESADO ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q446=+0.01 ;MATERIAL RESTANTE ~
    Q447=+10   ;DISTANCIA DE UNION ~
    Q448=+2    ;PROLONG. TRAYECTORIA
56 M99 ;Llamada al ciclo
57 FN 9: IF +0 EQU +0 GOTO LBL 1 ;Salto
58 ;
59 ;Subprograma para la última línea de contorno
60 LBL "ENDE1"
Q61 = Q60 ;Profundidad final
Q62 = Q61 + ( Q65 - SIN Q50 * Q65 ) ;Coordenada Z teniendo en cuenta el radio de la herramienta R2
Q63 = ( Q52 - TAN Q50 * Q61 ) + ( Q65 - COS Q50 * Q65 ) ;Calcular la sobremedida para líneas de contorno
61 CYCL DEF 25 TRAZADO CONTORNO ~
   Q1=-Q62  ;PROFUNDIDAD FRESADO ~
    Q3=-Q63  ;SOBREMEDIDA LATERAL ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q7=+2    ;ALTURA DE SEGURIDAD ~
    Q10=-Q62  ;PASO PROFUNDIZACION ~
    Q11= AUTO ;AVANCE PROFUNDIDAD ~
    Q12= AUTO ;AVANCE PARA DESBASTE ~
    Q15=+1    ;TIPO DE FRESADO ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q446=+0.01 ;MATERIAL RESTANTE ~
    Q447=+10   ;DISTANCIA DE UNION ~
    Q448=+2    ;PROLONG. TRAYECTORIA
62 M99 ;Llamada al ciclo
63 L  Z+20 R0 FMAX ;Retirar la hta.
64 LBL 0
65 END PGM 3255_ES MM