0  BEGIN PGM 4040_ES MM 
1  BLK FORM 0.1 Z X-100 Y-100 Z-100
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  ;Fresar isla circular
4  ;Llamada a la herramienta
5  TOOL CALL 10 Z S3000 F800
6  L  X+0  Y+0  Z+100 R0 FMAX M3
7  CYCL DEF 257 ISLA CIRCULAR ~
    Q223=+200  ;DIAMETRO TERMINADO ~
    Q222=+283  ;DIAMETRO BRUTO ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q207= AUTO ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-80   ;PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q206= AUTO ;AVANCE PROFUNDIDAD ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q370=+1    ;SOLAPAM. TRAYECTORIA
8  M99
9  L  Z+100 R0 FMAX M5
10 ;Fresar ranuras en superficie cilíndrica
11 ;Llamada a la herramienta
12 TOOL CALL 2 Z S5000 F500
13 ;Desplazar a una posición segura para inclinar el eje A
14 L  X+0  Y+0 R0 FMAX M3
15 M140 MB MAX F5000
16 ;Inclinar eje A
17 PLANE AXIAL  A-90 TURN FMAX
18 CALL LBL "MACHINING"
19 LBL "Loop"
20 ;Movimiento incremental del eje C
21 PLANE AXIAL IC+10 TURN FMAX
22 CALL LBL "MACHINING"
23 ;Repetición del paso
24 CALL LBL "Loop" REP34
25 M140 MB MAX F5000
26 PLANE RESET TURN FMAX
27 M30 ;Final del programa
28 ;Subprograma
29 LBL "MACHINING"
30 ;Ciclo de mecanizado
31 ;Importante, coordenadas de la superficie = radio del cilindro
32 CYCL DEF 253 FRESADO RANURA ~
    Q215=+0    ;TIPO MECANIZADO ~
    Q218=+20   ;LONGITUD RANURA ~
    Q219=+5    ;ANCHURA RANURA ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q374=+100  ;ANGULO GIRO ~
    Q367=+0    ;POSICION RANURA ~
    Q207=+500  ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-5    ;PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q369=+0    ;SOBREMEDIDA PROFUND. ~
    Q206=+150  ;AVANCE PROFUNDIDAD ~
    Q338=+0    ;PASADA PARA ACABADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+100  ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q366=+0    ;PUNZONAR ~
    Q385=+500  ;AVANCE ACABADO
33 ;Posición con llamada de ciclo
34 L  X+0  Y+25 R0 FMAX M99
35 LBL 0
36 END PGM 4040_ES MM