0  BEGIN PGM 4225_ES MM 
1  ;Programa para ejecutar varios mecanizados
2  ;situados en una recta con una herramienta
3  ;inclinada.
4  ;En este ejemplo se fresa en primer lugar
5  ;una cajera con una fresa para crear una
6  ;superficie. En un segundo paso de mecanizado,
7  ;se generan los taladros perpendicularmente a
8  ;la superficie inferior de la cajera.
9  ;En primer lugar, se deben definir todos los
10 ;parámetros necesarios. Asimismo, deben
11 ;ajustarse los datos de herramienta y, en caso
12 ;necesario, los ciclos.
13 ;¡IMPORTANTE! El programa se ha creado para
14 ;máquinas configuradas para la inclinación del
15 ;espacio de trabajo con un ángulo espacial. Si
16 ;la máquina solo trabaja con ángulos del eje,
17 ;también se deben modificar las entradas en el
18 ;ciclo 19. Antes de la inclinación, también se
19 ;debe desplazar a una posición segura que
20 ;depende de la máquina para evitar el riesgo de
21 ;colisiones al desplazar los ejes rotativos.
22 ;
23 ;
24 BLK FORM 0.1 Z X+0 Y+0 Z-30
25 BLK FORM 0.2  X+100  Y+100  Z+0
26 ;
27 ;Introducción de parámetros
28 ;Posición y ubicación de los taladros
29 FN 0: Q10 =+15 ;COORDENADA PRIMER MECANIZADO EN X
30 FN 0: Q11 =+15 ;COORDENADA PRIMER TALADRO EN Y
31 FN 0: Q12 =+10 ;DISTANCIA DE LOS TALADROS EN EL 
32 ;              ;EJE X
33 FN 0: Q13 =+10 ;DISTANCIA DE LOS TALADROS EN EL 
34 ;              ;EJE Y
35 FN 0: Q14 =+8 ;NÚMERO DE TALADROS
36 FN 0: Q15 =+30 ;ÁNGULO ESPACIAL A DEL MECANIZADO
37 FN 0: Q16 =+0 ;ÁNGULO ESPACIAL B DEL MECANIZADO
38 FN 0: Q17 =-150 ;ÁNGULO ESPACIAL C DEL MECANIZADO
39 ;Parámetro para fresar la cajera
40 FN 0: Q2 =+3 ;PROFUNDIDAD DE LA CAJERA
41 FN 0: Q3 =+8 ;DIÁMETRO DE LA CAJERA
42 FN 0: Q18 =+400 ;AVANCE FRESADO DE CAJERA
43 ;Parámetro para el taladrado
44 FN 0: Q4 =+20 ;PROFUNDIDAD TALADRO
45 FN 0: Q19 =+500 ;AVANCE TALADRADO
46 ;Fin de la introducción de parámetros
47 ;
48 ;variables
49 FN 2: Q1 =+Q14 - +2 ;Número de repeticiones
50 ;Fin de los cálculos
51 ;
52 M3
53 ;Llamada de herramienta fresa de mango para el centrado
54 TOOL CALL 2 Z S2000 F300
55 ;Llamada de subprograma para Reset
56 CALL LBL 10
57 ;Ciclo para realizar superficie plana / centrado
58 CYCL DEF 252 CAJERA CIRCULAR ~
    Q215=+0    ;TIPO MECANIZADO ~
    Q223=+Q3   ;DIAMETRO CIRCULO ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q207=+Q18  ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-Q2   ;PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q369=+0    ;SOBREMEDIDA PROFUND. ~
    Q206=+Q18  ;AVANCE PROFUNDIDAD ~
    Q338=+0    ;PASADA PARA ACABADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q370=+1    ;SOLAPAM. TRAYECTORIA ~
    Q366=+1    ;PUNZONAR ~
    Q385=+500  ;AVANCE ACABADO
59 ;Llamada de subprograma para posicionamiento y
60 ;mecanizado
61 CALL LBL 3
62 ;Retirar la hta.
63 L  Z+50 F2222
64 ;
65 ;Llamada de herramienta Broca
66 TOOL CALL 227 Z S1000 F300
67 ;Definición ciclo de taladrar
68 CYCL DEF 200 TALADRADO ~
    Q200=+5    ;DISTANCIA SEGURIDAD ~
    Q201=-Q4   ;PROFUNDIDAD ~
    Q206=+Q19  ;AVANCE PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q210=+0    ;TIEMPO ESPERA ARRIBA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q211=+0    ;TIEMPO ESPERA ABAJO ~
    Q395=+0    ;REFER. PROF.
69 ;Llamada de subprograma para posicionamiento y
70 ;mecanizado
71 CALL LBL 3
72 ;Retirar la herramienta y final del programa
73 L  Z+50 F2222 M30
74 ;
75 ;Subprograma para posicionamiento y centrado
76 LBL 3
77 ;Desplazamiento del punto cero en el primer
78 ;mecanizado
79 CYCL DEF 7.0 PUNTO CERO
80 CYCL DEF 7.1  Y+Q10
81 CYCL DEF 7.2  X+Q11
82 ;Inclinación del plano de mecanizado
83 CYCL DEF 19.0 PLANO DE TRABAJO
84 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
85 ;Ir a posición segura
86 M140 MB MAX F9999
87 ;Posicionamiento de los ejes rotativos
88 L  A+Q120  B+Q121  C+Q122 R0 FMAX
89 ;Aproximación de la primera posición de mecanizado
90 L  X+0  Y+0  Z+50 R0 FMAX M3
91 ;Llamada al ciclo
92 M99
93 ;Repetición parcial del programa para los siguientes
94 ;mecanizados
95 LBL 2
96 ;Llamada de subprograma para siguientes mecanizados
97 CALL LBL 1
98 ;Llamada de las repeticiones
99 CALL LBL 2 REPQ1
100 ;Retirar la hta.
101 M140 MB MAX F9999
102 ;Llamada de subprograma para Reset
103 CALL LBL 10
104 ;Deshacer inclinación de los ejes rotativos
105 L  A+Q120  B+Q121  C+Q122 R0 FMAX
106 ;Reset del desplazamiento del punto cero
107 CYCL DEF 7.0 PUNTO CERO
108 CYCL DEF 7.1  Y+0
109 CYCL DEF 7.2  X+0
110 LBL 0
111 ;
112 ;Subprograma para siguientes mecanizados
113 LBL 1
114 ;Llamada de subprograma para Reset
115 CALL LBL 10
116 ;Desplazamiento incremental del punto cero en la
117 ;siguiente posición
118 CYCL DEF 7.0 PUNTO CERO
119 CYCL DEF 7.1 IX+Q12
120 CYCL DEF 7.2 IY+Q13
121 ;Inclinación del plano de mecanizado
122 CYCL DEF 19.0 PLANO DE TRABAJO
123 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
124 ;Aproximar posición de mecanizado
125 L  X+0  Y+0  Z+50 R0 FMAX
126 ;Llamada al ciclo
127 M99
128 ;Llamada de subprograma para Reset
129 CALL LBL 10
130 LBL 0
131 ;
132 ;Subprograma para Reset
133 LBL 10
134 ;Deshacer la inclinación del espacio de trabajo
135 CYCL DEF 19.0 PLANO DE TRABAJO
136 CYCL DEF 19.1  A+0  B+0  C+0
137 ;Deseleccionar la inclinación del espacio de trabajo
138 CYCL DEF 19.0 PLANO DE TRABAJO
139 CYCL DEF 19.1
140 ;Reset factor de escala
141 CYCL DEF 11.0 FACTOR ESCALA
142 CYCL DEF 11.1 SCL 1
143 ;Reset rotación
144 CYCL DEF 10.0 GIRO
145 CYCL DEF 10.1  ROT+0
146 LBL 0
147 END PGM 4225_ES MM