0 BEGIN PGM 42301_ES MM 
1 ;Programa NC para el cálculo y el mecanizado del
2 ;tornillo transportador.
3 ;Además, en la parte del programa "SUBLOOP" se
4 ;programa el contorno en el plano X/Y. Puesto que
5 ;en este caso se trata de un contorno que se compone
6 ;de tres tramos iguales, se ha programado una vez
7 ;y luego se ha repetido dos veces girando 120°.
8 ;Para poder realizar los cortes traseros en la pieza
9 ;es necesario ajustar la herramienta.
10 ;Para ello se emplea la función TCPM, de modo que el
11 ;sistema de coordenadas permanece sin cambios. Pero
12 ;al desplazar los ejes rotativos, el control numérico
13 ;tiene en cuenta la cinemática y conduce el
14 ;Tool Center Point, en este caso el centro de la fresa
15 ;esférica, a lo programado.
16 ;Los movimientos de compensación del eje C, que en las
17 ;trayectorias circulares del contorno están programados en
18 ;este programa, están seleccionados de tal modo que no se
19 ;originen daños en el contorno.
20 ;
21 ;Inicio del programa
Q10 = Q9 ;profundidad actual
Q12 = Q2 / Q1 ;Rotación por cada milímetro de profundidad
Q20 = 5 + Q108 + Q7 ;Primer radio incluido el radio de la herramienta y la sobremedida
Q30 = Q6 - ( ( Q6 - ( 25 + Q20 ) ) / 2 ) ;Centro del círculo para una aproximación suave
22 PLANE RESET STAY ;Anular la inclinación
23 L  Z+Q5 R0 FMAX M3 ;Aproximación a altura segura
24 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL AXIS ;Activar la función TCPM
25 CC  X+0  Y+0 ;Centro del círculo para el posicionamiento previo
26 LP  PR+Q6  PA+0 R0 FMAX ;Posicionamiento previo
27 L  B+Q4  A+0  C+0 R0 FMAX ;Aproximación del ángulo de ajuste del eje B
28 ;
29 ;Label para repetición
30 LBL "MAINLOOP"
Q11 = Q10 * Q12 ;Calcular la rotación actual
31 ;
32 ;Giro del sistema de coordenadas
33 CYCL DEF 10.0 DREHUNG
34 CYCL DEF 10.1  ROT+Q11
35 ;
36 L  C+Q11 R0 FMAX ;Movimiento de compensación del eje C
37 L  Z+Q10 R0 FMAX ;Desplazarse a la nueva coordenada Z
38 CC  X+0  Y+0 ;Centro para el posicionamiento previo
39 LP  PR+Q6  PA+0 R0 FMAX ;Posicionamiento previo a un radio seguro
40 CC  X+Q30  Y+0 ;Centro del círculo para el movimiento de aproximación
41 CP  PA+180 DR- F AUTO ;Movimiento de aproximación
42 CC  X+25  Y+0 ;Movimiento de aproximación
43 ;
44 ;Repetición parcial del programa
45 ;en la que se describe el contorno
46 LBL "SUBLOOP"
47 CP  PA+123.5 IC+33.5 DR+
48 CC  X+15.82  Y+13.86
49 CP IPA-102.6 IC+29.3 DR-
50 CC  X-23.05  Y-1.02
51 CP IPA+44.1 IC+48.8 DR+
52 CYCL DEF 10.0 DREHUNG
53 CYCL DEF 10.1 IROT+120
54 CC  X+25  Y+0
55 CP  PA+0 IC+8.4 DR+
56 CALL LBL "SUBLOOP" REP2
57 ;
58 CC  X+Q30  Y+0 ;Centro del círculo para el movimiento de alejamiento
59 CP  PA+0 DR- F AUTO ;Desplazarse a una posición segura
60 L  Z+Q5 R0 FMAX ;Desplazarse a altura de seguridad
61 LBL 0
62 ;
Q10 = Q10 + Q3 ;Calcular nueva coordenada Z
63 FN 11: IF +Q10 GT +Q1 GOTO LBL "MAINLOOP" ;Compara si se ha alcanzado la profundidad y, dado el caso, hacer salto
64 FN 0: Q10 =+Q1 ;Coordenada Y igual a profundidad
65 ;Salto al fresado de contorno
66 CALL LBL "MAINLOOP"
67 L  B+0  C+0  A+0 R0 FMAX M5 ;Reponer la posición de todos los ejes rotativos
68 FUNCTION RESET TCPM ;Reiniciar la función TCPM
69 ;Final del programa
70 END PGM 42301_ES MM