BEGIN PGM 4240_es MM 
;Programa NC para mecanizar cuatro piezas
;con una pirámide de sujeciones.
;En cada una de las piezas, el control
;numérico tiene que fresar un chaflán
;con 5*45 grados con las dimensiones
;60*60*60mm,. El mecanizado se realiza
;con una fresadora de mango inclinada.
;
;Las piezas están sujetas a una pirámide
;de sujeciones con un ángulo de 45 grados.
;
;Las piezas se disponen del modo siguiente:
;Pieza 1 -> PRESET 6 --> Delante
;Pieza 2 -> PRESET 7 --> Derecha
;Pieza 3 -> PRESET 8 --> Detrás
;Pieza 4 -> PRESET 9 --> Izquierda
;
;La mecanización de la pieza se programa en
;el subprograma "MACHINING".
;El control numérico mecaniza este
;subprograma en cada preset con el ángulo
;modificado para la alineación.
;Es importante que los ángulos para alinear
;la pirámide de sujeciones figuren
;respectivamente en los parámetros
;QR170, QR171 y QR172.
;En el subprograma "MACHINING" primero está
;definida la herramienta. A continuación,
;el control numérico llama un
;LBL "TILT..." y el LBL "MILL" para cada
;una de las superficies a fresar.
;En los subprogramas "TILT..." está el
;desplazamiento del punto cero y la
;inclinación del plano de mecanizado del
;correspondiente mecanizado en relación al
;sistema de coordenadas de la pieza.
;A continuación el control numérico llama
;al LBL "TILT_NEW".
;En este subprograma, el control numérico
;calcula entonces a partir de los ángulos
;para la alineación de la posición de
;sujeción, del desplazamiento del punto cero
;y de la inclinación del plano de
;mecanizado, el ángulo espacial resultante
;y el desplazamiento del punto cero y los
;activa. A continuación se realiza el
;mecanizado que está programado en
;LBL "MILL".
;
;
* -Definición de la cara 1 -> DELANTE
CYCL DEF 247 FIJAR PTO. REF. ~
   Q339=+6    ;NUMERO PUNTO REFER.
;SPA alineado = QR170
QR170 = 45
;SPB alineado = QR171
QR171 = 0
;SPC alineado = QR172
QR172 = 0
CALL LBL "MACHINING"
;
* -Definición de la cara 2 -> DERECHA
CYCL DEF 247 FIJAR PTO. REF. ~
   Q339=+7    ;NUMERO PUNTO REFER.
;SPA alineado = QR170
QR170 = 45
;SPB alineado = QR171
QR171 = 0
;SPC alineado = QR172
QR172 = 90
CALL LBL "MACHINING"
;
* -Definición de la cara 3 -> DETRAS
CYCL DEF 247 FIJAR PTO. REF. ~
   Q339=+8    ;NUMERO PUNTO REFER.
;SPA alineado = QR170
QR170 = 45
;SPB alineado = QR171
QR171 = 0
;SPC alineado = QR172
QR172 = 180
CALL LBL "MACHINING"
;
* -Definición de la cara 4 -> IZQUIERDA
CYCL DEF 247 FIJAR PTO. REF. ~
   Q339=+9    ;NUMERO PUNTO REFER.
;SPA alineado = QR170
QR170 = 45
;SPB alineado = QR171
QR171 = 0
;SPC alineado = QR172
QR172 = 270
CALL LBL "MACHINING"
;
;Reiniciar todos los cálculo de coordenadas
CALL LBL "RESET"
;
;Final del programa
M30
;
;Subprogramas
* - MECANIZADO
LBL "MACHINING"
* -Fresar superficies 45
TOOL CALL "D16" Z S9000 F2000
CALL LBL "SAFE"
CALL LBL "TILT1"
CALL LBL "MILL"
CALL LBL "TILT2"
CALL LBL "MILL"
CALL LBL "TILT3"
CALL LBL "MILL"
CALL LBL "TILT4"
CALL LBL "MILL"
LBL 0
;
* -  Fresar
LBL "MILL"
L  X-20  Y+5  Z+50 R0 FMAX
L  Z+5 R0 FMAX
L  Z+0 R0 F2000
APPR LT  X+0  Y-1 LEN10 RL F AUTO
L  X+60
DEP LT LEN10
L  Z+50 R0 FMAX
LBL 0
;
* - Inclinar = 0 grados
LBL "TILT0"
PLANE RESET STAY
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X+0
CYCL DEF 7.2  Y+0
CYCL DEF 7.3  Z+0
CALL LBL "SAFE"
PLANE SPATIAL SPA+0 SPB+0 SPC+0 STAY SEQ-
;Convertir sobre el plano
CALL LBL "TILT_NEW"
LBL 0
;
* - Inclinar 1
LBL "TILT1"
PLANE RESET STAY
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X-30
CYCL DEF 7.2  Y-30
CYCL DEF 7.3  Z-5
CALL LBL "SAFE"
PLANE SPATIAL SPA+45 SPB+0 SPC+0 STAY SEQ-
;Convertir sobre el plano
CALL LBL "TILT_NEW"
LBL 0
;
* - Inclinar 2
LBL "TILT2"
PLANE RESET STAY
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X+30
CYCL DEF 7.2  Y-30
CYCL DEF 7.3  Z-5
CALL LBL "SAFE"
PLANE SPATIAL SPA+45 SPB+0 SPC+90 STAY SEQ-
;Convertir sobre el plano
CALL LBL "TILT_NEW"
LBL 0
;
* - Inclinar 3
LBL "TILT3"
PLANE RESET STAY
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X+30
CYCL DEF 7.2  Y+30
CYCL DEF 7.3  Z-5
CALL LBL "SAFE"
PLANE SPATIAL SPA+45 SPB+0 SPC+180 STAY SEQ-
;Convertir sobre el plano
CALL LBL "TILT_NEW"
LBL 0
;
* - Inclinar 4
LBL "TILT4"
PLANE RESET STAY
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X-30
CYCL DEF 7.2  Y+30
CYCL DEF 7.3  Z-5
CALL LBL "SAFE"
PLANE SPATIAL SPA+45 SPB+0 SPC+270 STAY SEQ-
;Convertir sobre el plano
CALL LBL "TILT_NEW"
LBL 0
;
* - Posición segura
LBL "SAFE"
M3
L  Z+300 R0 FMAX M91
L  X+400  Y-300 R0 FMAX M91
LBL 0
;
* - Reinicio de todos los cálculos de coordenadas
LBL "RESET"
CALL LBL "SAFE"
PLANE RESET TURN FMAX
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X+0
CYCL DEF 7.2  Y+0
CYCL DEF 7.3  Z+0
CYCL DEF 8.0 ESPEJO
CYCL DEF 8.1
CYCL DEF 10.0 GIRO
CYCL DEF 10.1  ROT+0
CYCL DEF 11.0 FACTOR ESCALA
CYCL DEF 11.1 SCL 1
LBL 0
;
* - Cálculo del ángulo
LBL "TILT_NEW"
;Leer 3 D ROT
FN 18: SYSREAD Q170 = ID210 NR5 IDX1 ;3D ROT SPA
FN 18: SYSREAD Q171 = ID210 NR5 IDX2 ;3D ROT SPB
FN 18: SYSREAD Q172 = ID210 NR5 IDX3 ;3D ROT SPC
PLANE RESET STAY
;Leer Desplazamiento punto cero
FN 18: SYSREAD Q175 = ID220 NR2 IDX1 ;punto cero X
FN 18: SYSREAD Q176 = ID220 NR2 IDX2 ;punto cero Y
FN 18: SYSREAD Q177 = ID220 NR2 IDX3 ;punto cero Z
;Inclinar alineación
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1  X+0
CYCL DEF 7.2  Y+0
CYCL DEF 7.3  Z+0
PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 STAY
;Desplazamiento del punto cero en la superficie alineada
CYCL DEF 7.0 PUNTO CERO
CYCL DEF 7.1 IX+Q175
CYCL DEF 7.2 IY+Q176
CYCL DEF 7.3 IZ+Q177
;Inclinar después el ROT 3D leído
PLANE RELATIV SPC+Q172 STAY
PLANE RELATIV SPB+Q171 STAY
CALL LBL "SAFE"
PLANE RELATIV SPA+Q170 TURN FMAX SEQ-
LBL 0
END PGM 4240_es MM