0 BEGIN PGM 50051_ES MM 
1 ;Programa para mecanizar una isla circular y a
2 ;continuación fresar la superficie oblicua.
3 ;
4 ;Llamada a la herramienta
5 TOOL CALL 15 Z S4000 F300
6 ;
7 L  Z+100 R0 FMAX M3 ;Desplazarse a altura de seguridad
8 L  X+Q7  Y+Q8 R0 FMAX ;Posicionamiento previo
9 FN 3: Q80 =+Q1 * +2 ;Cálculo del diámetro
10 ;Definición isla circular
11 CYCL DEF 257 KREISZAPFEN ~
   Q223=+Q80  ;FERTIGTEIL-DURCHM. ~
    Q222=+141  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-50   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
12 M99
13 L  X+Q7  Y+Q8  Z+100 R0 FMAX
14 ;Desplazar punto cero al centro de la isla.
15 ;Desplazamiento Z a la posición en torno a
16 ;la cual se va a inclinar el espacio de
17 ;trabajo.
18 CYCL DEF 7.0 NULLPUNKT
19 CYCL DEF 7.1  Z+Q9
20 CYCL DEF 7.2  X+Q7
21 CYCL DEF 7.3  Y+Q8
22 ;Inclinación del espacio de trabajo
23 CYCL DEF 19.0 BEARBEITUNGSEBENE
24 CYCL DEF 19.1  A+Q11  B+0  C+0
25 ;Desplazar ejes rotativos a la posición
26 L  A+Q120  B+Q121  C+Q122 R0 FMAX
27 ;Ciclo para definir el mecanizado de superficies
28 ;planas
29 CYCL DEF 232 PLANFRAESEN ~
   Q389=+2    ;STRATEGIE ~
    Q225=-Q1   ;STARTPUNKT 1. ACHSE ~
    Q226=-60   ;STARTPUNKT 2. ACHSE ~
    Q227=+40   ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+Q80  ;1. SEITEN-LAENGE ~
    Q219=+120  ;2. SEITEN-LAENGE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
30 M99
31 M140 MB MAX F9999 ;Retirar la hta.
32 ;Cancelar la inclinación del espacio de trabajo
33 CYCL DEF 19.0 BEARBEITUNGSEBENE
34 CYCL DEF 19.1  A+0  B+0  C+0
35 CYCL DEF 19.0 BEARBEITUNGSEBENE
36 CYCL DEF 19.1
37 ;Restablecer los ejes rotativos a cero
38 L  A+Q120  B+Q121  C+Q122 R0 FMAX
39 ;Cancelar decalaje de punto cero
40 CYCL DEF 7.0 NULLPUNKT
41 CYCL DEF 7.1  X+0
42 CYCL DEF 7.2  Y+0
43 CYCL DEF 7.3  Z+0
44 END PGM 50051_ES MM