0 BEGIN PGM 5025_ES MM 
1 ;Programa para desbarbar con una fresa de
2 ;moldeo un taladro que se ha realizado en
3 ;la superficie exterior del cilindro
4 ;formando ángulo recto con el eje del
5 ;cilindro.
6 ;El mecanizado se realiza en los tres ejes
7 ;lineales sin inclinar el espacio de
8 ;trabajo.
9 ;En primer lugar, se deben definir todos
10 ;los parámetros necesarios. A continuación,
11 ;en este programa tiene lugar una parte del
12 ;programa de llamada de herramienta,
13 ;posicionamiento y ciclo de mecanizado para
14 ;realizar el taladro.
15 ;También en esta parte del programa se deben
16 ;definir todos los parámetros, ya que los
17 ;parámetros descritos anteriormente solo
18 ;están activos para el desbarbado.
19 ;Tras el mecanizado del taladro se define la
20 ;herramienta con la que debe realizarse el
21 ;desbarbado. A continuación, el control
22 ;numérico calcula las coordenadas para los
23 ;ejes individuales y hace la aproximación
24 ;correspondiente.
25 ;A continuación, el control numérico calcula
26 ;cada vez el siguiente punto con su
27 ;coordenada X, Y y Z y las aproxima. Esto se
28 ;repite las veces que haga falta hasta que
29 ;se haya vuelto a alcanzar el punto inicial.
30 ;Debe definirse en cuántos puntos se divide
31 ;el mecanizado con el parámetro DIVISIÓN.
32 ;Importante El control numérico calcula el
33 ;movimiento de trayectoria para el centro de
34 ;la herramienta. Con el parámetro
35 ;DESVIACIÓN CENTRO DE HERRAMIENTA RESPECTO
36 ;AL RADIO (Q7) se define cuán lejos se lleva
37 ;el centro de la herramienta del borde del
38 ;taladro. Al hacerlo se debe tener en cuenta
39 ;el signo: si el signo tiene valor positivo,
40 ;la trayectoria del centro es superior al
41 ;radio, y si tiene valor negativo, es
42 ;inferior.
43 ;
44 ;Introducción de parámetros
45 FN 0: Q3 =+100 ;RADIO DEL CILINDRO
46 FN 0: Q4 =+100 ;GRADUACIÓN
47 FN 0: Q5 =+3 ;DETERMINAR PROFUNDIDAD POSITIVA
48 FN 0: Q1 =+0 ;CENTRO TALADRO EN X
49 FN 0: Q6 =+60 ;RADIO TALADRO
50 FN 0: Q7 =-0.5 ;DESVIACIÓN CENTRO DE HERRAMIENTA RESPECTO AL RADIO
51 FN 0: Q10 =+20 ;DISTANCIA DE SEGURIDAD
52 FN 0: Q11 =+1000 ;AVANCE AL PROFUNDIZAR
53 FN 0: Q12 =+2000 ;AVANCE DE FRESADO
54 ;Fin de la introducción de parámetros
55 ;
56 BLK FORM CYLINDER X RQ3 L200 DIST+100
57 ;
58 ;Desplazar punto cero al centro del
59 ;taladro y superficie del cilindro
60 CYCL DEF 7.0 NULLPUNKT
61 CYCL DEF 7.1  X+Q1
62 CYCL DEF 7.2  Z+Q3
63 ;
64 ;Llamada a la herramienta para el taladro
65 TOOL CALL 8 Z S3000 F800
66 ;
67 L  Z+100 R0 FMAX M3 ;Desplazarse a altura de seguridad
68 L  X+0  Y+0 R0 FMAX ;Desplazarse al centro del taladro
69 L  Z+Q10 R0 FMAX ;Desplazarse a la distancia de seguridad
70 FN 3: Q80 =+Q6 * +2 ;Cálculo diámetro taladro
71 ;Ciclo para el taladrado
72 CYCL DEF 252 KREISTASCHE ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+Q80  ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-100  ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+300  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
73 M99
74 L  Z+100 R0 FMAX ;Retirar la hta.
75 ;
76 ;Llamada de herramienta para el desbarbado
77 TOOL CALL 170 Z S12000
78 ;
79 L  Z+100 R0 FMAX M3 ;Desplazarse a altura de seguridad
80 CALL LBL 1 ;Llamada del mecanizado
81 ;
82 ;Retirar la hta. y final del programa
83 L  Z+100 R0 FMAX M30
84 ;
85 ;Subprogramas para el mecanizado
86 LBL 1
87 FN 0: Q23 =+Q5 ;primera profundidad igual a la profundidad teórica
88 FN 0: Q24 =+0 ;Contador
89 FN 1: Q26 =+Q6 + +Q7 ;Compensación del desplazamiento de la fresa
90 FN 0: Q27 =+0 ;Ángulo inicial
91 FN 4: Q37 =+360 DIV +Q4 ;Paso angular
92 CALL LBL 10 ;Llamada cálculos
93 L  X+Q21  Y+Q22 FMAX ;Desplazarse a la primera posición
94 L  Z+Q10 R0 FMAX ;Desplazarse a la distancia de seguridad
95 L  Z-Q23 FQ11 ;Desplazar a profundidad
96 LBL 2 ;Repeticiones
97 FN 1: Q24 =+Q24 + +1 ;Actualización del contador
98 FN 1: Q27 =+Q27 + +Q37 ;Actualización del ángulo
99 CALL LBL 10 ;Llamada cálculos
100 L  X+Q21  Y+Q22  Z-Q23 FQ12 ;Desplazarse a la nueva posición
101 FN 12: IF +Q24 LT +Q4 GOTO LBL 2 ;Comparación de si se ha alcanzado el número de repeticiones
102 LBL 0
103 LBL 10 ;Cálculos
Q21 = Q26 * COS Q27 ;Nueva posición X
Q22 = Q26 * SIN Q27 ;Nueva posición Y
Q23 = Q3 - ( SQRT ( Q3 * Q3 - Q22 * Q22 ) ) + Q5 ;Nueva posición Z
104 LBL 0
105 END PGM 5025_ES MM