0  BEGIN PGM 5080-ES MM 
1  ;En este programa se mecanizan una isla
2  ;rectangular y una cajera rectangular,
3  ;así como una isla circular y una cajera
4  ;circular y, a continuación, se fresa
5  ;un bisel en los contornos
6  ;circunferencialmente con una
7  ;herramienta inclinada. El mecanizado
8  ;de los contornos se programa en el
9  ;programa principal, para cada bisel se
10 ;llama a otro programa en el que deben
11 ;introducirse los parámetros
12 ;correspondientes.
13 ;
14 BLK FORM 0.1 Z X+0 Y+0 Z-20
15 BLK FORM 0.2  X+200  Y+100  Z+2
16 ;Llamada a la herramienta
17 TOOL CALL 12 Z S6121 F4591
18 TOOL DEF 8
19 CYCL DEF 232 FRESADO PLANO ~
    Q389=+2    ;ESTRATEGIA ~
    Q225=+0    ;PTO. INICIAL 1ER EJE ~
    Q226=+0    ;PTO. INICIAL 2. EJE ~
    Q227=+2    ;PTO. INICIAL 3ER EJE ~
    Q386=+0    ;PUNTO FINAL 3ER EJE ~
    Q218=+200  ;1A LONGITUD LATERAL ~
    Q219=+100  ;2A LONGITUD LATERAL ~
    Q202=+5    ;MAX. PROF. PASADA ~
    Q369=+0    ;SOBREMEDIDA PROFUND. ~
    Q370=+1    ;MAX. SOLAPAMIENTO ~
    Q207= AUTO ;AVANCE DE FRESADO ~
    Q385= AUTO ;AVANCE ACABADO ~
    Q253= MAX ;AVANCE PREPOSICION. ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q357=+2    ;DIST. SEGUR. LATERAL ~
    Q204=+50   ;2A DIST. SEGURIDAD
20 CYCL CALL M3
21 ;
22 ;Llamada a la herramienta
23 TOOL CALL 8 Z S9549 F2578
24 ;Fresar contorno exterior con ciclo SL
25 CYCL DEF 14.0 CONTORNO
26 CYCL DEF 14.1 LABEL CONTORNO1 /2 /3
27 CYCL DEF 20 DATOS DEL CONTORNO ~
    Q1=-15   ;PROFUNDIDAD FRESADO ~
    Q2=+1    ;SOLAPAM. TRAYECTORIA ~
    Q3=+0    ;SOBREMEDIDA LATERAL ~
    Q4=+0    ;SOBREMEDIDA PROFUND. ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q6=+2    ;DISTANCIA SEGURIDAD ~
    Q7=+50   ;ALTURA DE SEGURIDAD ~
    Q8=+0    ;RADIO DE REDONDEO ~
    Q9=+1    ;SENTIDO DE GIRO
28 CYCL DEF 22 DESBASTE ~
    Q10=-7.5  ;PASO PROFUNDIZACION ~
    Q11= AUTO ;AVANCE PROFUNDIDAD ~
    Q12= AUTO ;AVANCE PARA DESBASTE ~
    Q18=+0    ;HERRAM. PREDESBASTE ~
    Q19=+2063 ;AVANCE OSCILACION ~
    Q208=+99999 ;AVANCE SALIDA
29 CYCL CALL M3
30 ;
31 ;Fresar cajeras
32 CYCL DEF 251 CAJERA RECTANGULAR ~
    Q215=+0    ;TIPO MECANIZADO ~
    Q218=+50   ;1A LONGITUD LATERAL ~
    Q219=+40   ;2A LONGITUD LATERAL ~
    Q220=+10   ;RADIO ESQUINA ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q224=+0    ;ANGULO GIRO ~
    Q367=+0    ;POSICION CAJERA ~
    Q207= AUTO ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-15   ;PROFUNDIDAD ~
    Q202=+8    ;PASO PROFUNDIZACION ~
    Q369=+0    ;SOBREMEDIDA PROFUND. ~
    Q206=+2063 ;AVANCE PROFUNDIDAD ~
    Q338=+0    ;PASADA PARA ACABADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q370=+1    ;SOLAPAM. TRAYECTORIA ~
    Q366=+1    ;PUNZONAR ~
    Q385=+500  ;AVANCE ACABADO
33 L  X+150  Y+50 R0 FMAX M3 M99
34 ;
35 CYCL DEF 252 CAJERA CIRCULAR ~
    Q215=+0    ;TIPO MECANIZADO ~
    Q223=+50   ;DIAMETRO CIRCULO ~
    Q368=+0    ;SOBREMEDIDA LATERAL ~
    Q207= AUTO ;AVANCE DE FRESADO ~
    Q351=+1    ;TIPO DE FRESADO ~
    Q201=-15   ;PROFUNDIDAD ~
    Q202=+8    ;PASO PROFUNDIZACION ~
    Q369=+0    ;SOBREMEDIDA PROFUND. ~
    Q206=+2063 ;AVANCE PROFUNDIDAD ~
    Q338=+0    ;PASADA PARA ACABADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q370=+1    ;SOLAPAM. TRAYECTORIA ~
    Q366=+1    ;PUNZONAR ~
    Q385=+500  ;AVANCE ACABADO
36 L  X+50  Y+50 R0 FMAX M3 M99
37 ;
38 TOOL CALL 8 Z S9549 F2500
39 M3
40 ;Decalaje del punto cero en el centro del círculo
41 CYCL DEF 7.0 PUNTO CERO
42 CYCL DEF 7.1  X+50
43 CYCL DEF 7.2  Y+50
44 ;Llamada programa Bisel círculo
45 CALL PGM 50801-es.h
46 ;Decalaje del punto cero en el centro del rectángulo
47 CYCL DEF 7.0 PUNTO CERO
48 CYCL DEF 7.1  X+150
49 CYCL DEF 7.2  Y+50
50 ;Llamada programa Bisel rectángulo
51 CALL PGM 50802-es.h
52 CYCL DEF 7.0 PUNTO CERO
53 CYCL DEF 7.1  X+0
54 CYCL DEF 7.2  Y+0
55 CYCL DEF 7.3  Z+0
56 ;
57 M30 ;Final del programa
58 ;Subprogramas
59 ;Contorno exterior
60 LBL 1
61 L  X-20  Y-20 RL
62 L  X+220
63 L  Y+120
64 L  X-20
65 L  Y-20
66 LBL 0
67 ;Contorno isla circular
68 LBL 2
69 CC  X+50  Y+50
70 LP  PR+35  PA+0 RL
71 CP IPA-360 DR-
72 LBL 0
73 ;Contorno isla rectangular
74 LBL 3
75 CC  X+150  Y+50
76 LP  PR+35  PA+0 RL
77 L  Y+20
78 RND R15
79 L IX-70
80 RND R15
81 L  Y+80
82 RND R15
83 L IX+70
84 RND R15
85 L  Y+50
86 LBL 0
87 END PGM 5080-ES MM