0  BEGIN PGM 51051_ES MM 
1  ;Programa NC para calcular la trayectoria
2  ;de herramienta para desbarbar una ranura
3  ;para chaveta.
4  ;Este programa NC se ha creado para que un
5  ;programa de mecanizado lo llame como ciclo.
6  ;La definición de los parámetros necesarios
7  ;se realiza en el programa de mecanizado
8  ;que se va a llamar. Por lo tanto, no se
9  ;deben realizar modificaciones en este
10 ;programa NC.
11 ;
12 FN 18: SYSREAD Q1 = ID270 NR1 IDX1 ;Leer posición X actual
13 FN 18: SYSREAD Q2 = ID270 NR1 IDX2 ;Leer posición Y actual
14 Q5 = Q203 + ABS Q200 ;Distancia de seguridad
15 Q6 = Q203 + ABS Q204 ;2. Distancia de seguridad
16 CYCL DEF 7.0 PUNTO CERO
17 CYCL DEF 7.1 IX+Q1
18 CYCL DEF 7.2 IY+Q2
19 CYCL DEF 10.0 GIRO
20 CYCL DEF 10.1 IROT+Q374
21 ;Posición de la ranura
22 Q7 = 0
23 FN 9: IF +Q367 EQU +0 GOTO LBL "END"
24 Q7 = ABS Q218 / 2
25 FN 9: IF +Q367 EQU +1 GOTO LBL "END"
26 Q7 = ( ABS Q218 - ABS Q219 ) / 2
27 FN 9: IF +Q367 EQU +2 GOTO LBL "END"
28 Q7 = NEG ( ABS Q218 - ABS Q219 ) / 2
29 FN 9: IF +Q367 EQU +3 GOTO LBL "END"
30 Q7 = NEG ABS Q218 / 2
31 LBL "END"
32 CYCL DEF 7.0 PUNTO CERO
33 CYCL DEF 7.1 IX+Q7
34 ;
35 Q10 = ( ABS Q218 - ABS Q219 ) / 2 ;X-MIN
36 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q219 / 2 ) )
37 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
38 Q13 = Q219 / 2 - Q108
39 L  X+0  Y+0  Z+Q6 R0 FMAX
40 L  Z+Q5 R0 FMAX
41 L  X+0  Y+0  Z+Q12 FQ207
42 APPR LCT  X+0  Y+Q13 R1 FQ207
43 L  X-Q10
44 Q20 = 90 ;Ángulo inicial
45 LBL 1
46 Q20 = Q20 + 1
47 Q21 = - Q10 + COS Q20 * Q13
48 Q22 = SIN Q20 * Q13
49 Q23 = SIN Q20 * Q219 / 2
50 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
51 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
52 L  X+Q21  Y+Q22  Z+Q12
53 CALL LBL 1 REP179
54 L  X+Q10
55 Q20 = - 90 ;Ángulo inicial
56 LBL 2
57 Q20 = Q20 + 1
58 Q21 = Q10 + COS Q20 * Q13
59 Q22 = SIN Q20 * Q13
60 Q23 = SIN Q20 * Q219 / 2
61 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
62 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
63 L  X+Q21  Y+Q22  Z+Q12
64 CALL LBL 2 REP179
65 L  X+0
66 DEP LCT  X+0  Y+0 R1
67 ;
68 CYCL DEF 7.0 PUNTO CERO
69 CYCL DEF 7.1  X+0
70 CYCL DEF 7.2  Y+0
71 CYCL DEF 7.3  Z+0
72 CYCL DEF 10.0 GIRO
73 CYCL DEF 10.1  ROT+0
74 L  Z+Q6 R0 FMAX
75 END PGM 51051_ES MM