0 BEGIN PGM 7100_es MM 
1 ;Programa para el mecanizado exterior de
2 ;una semiesfera con una fresa esférica.
3 ;El mecanizado se realiza en líneas de
4 ;contorno, de modo que la trayectoria de
5 ;fresado transcurra en el plano X/Y y la
6 ;aproximación en el plano X/Z.
7 ;
8 BLK FORM 0.1 Z X-50 Y-50 Z-55
9 BLK FORM 0.2  X+50  Y+50  Z+0
10 ;
11 ;Introducción de parámetros
12 FN 0: Q1 =+0 ;CENTRO DE LA ESFERA EN EL EJE X
13 FN 0: Q2 =+0 ;CENTRO DE LA ESFERA EN EL EJE Y
14 FN 0: Q3 =-50 ;CENTRO DE LA ESFERA EN EL EJE Z
15 FN 0: Q4 =+50 ;RADIO ESFERA
16 FN 0: Q5 =+45 ;NÚMERO DE LÍNEAS DEL CONTORNO
17 FN 0: Q6 =+3 ;DISTANCIA DE SEGURIDAD
18 FN 0: Q7 =+500 ;AVANCE AL PROFUNDIZAR
19 FN 0: Q8 =+800 ;AVANCE DE FRESADO
20 FN 0: Q9 =+5 ;RADIO DE LA ESFERA HERRAMIENTA
21 ;Fin de la introducción de parámetros
22 ;
23 ;Llamada a la herramienta fresa esférica
24 TOOL CALL 157 Z S8000 DL-Q9
25 ;
26 ;
27 ;Cálculos
28 FN 1: Q10 =+Q4 + +Q9 ;Radio efectivo en el centro de la herramienta
29 FN 1: Q11 =+Q10 + +Q6 ;Radio para el posicionamiento previo
30 FN 4: Q12 =+90 DIV +Q5 ;Paso angular
31 FN 2: Q13 =+Q5 - +1 ;Número de repeticiones
32 ;Fin de los cálculos
33 ;
34 ;Posicionamiento previo
35 L  Z+200 R0 FMAX
36 L  X+Q1  Y+Q2 R0 F9999 M3
37 CC  X+Q1  Z+Q3
38 LP  PR+Q11  PA+0 R0 FMAX
39 LP  PR+Q10 R0 FQ7
40 LBL 1 ;Repeticiones
41 CC  Z+Q3  X+Q1
42 CP IPA+Q12 DR+ FQ7
43 CC  X+Q1  Y+Q2
44 CP IPA+360 DR+ FQ8
45 CALL LBL 1 REPQ13
46 ;
47 ;Final del programa
48 L  Z+100 R0 FMAX M30
49 END PGM 7100_es MM