0 BEGIN PGM 7110_es MM 
1 ;Programa para el mecanizado exterior de
2 ;una semiesfera con una fresa cilíndrica.
3 ;Se fresa en una trayectoria X/Z desde
4 ;abajo hacia arriba. Este movimiento se
5 ;subdivide en trayectorias lineales
6 ;individuales. A continuación se gira el
7 ;sistema de coordenadas y se recorre la
8 ;trayectoria siguiente.
9 ;Mediante las graduaciones definidas se
10 ;determina la precisión y la calidad de
11 ;la superficie.
12 ;
13 ;Introducción de parámetros
14 FN 0: Q1 =+55 ;CENTRO DE LA ESFERA EN EL EJE X
15 FN 0: Q2 =+55 ;CENTRO DE LA ESFERA EN EL EJE Y
16 FN 0: Q3 =-50 ;CENTRO DE LA ESFERA EN EL EJE Z
17 FN 0: Q4 =+50 ;RADIO ESFERA
18 FN 0: Q5 =+60 ;GRADUACIÓN EN EL PLANO X/Y
19 ;             ;DEFINE ENTRE CUÁNTAS 
20 ;             ;TRAYECTORIAS DE FRESADO SE 
21 ;             ;REPARTEN LOS 360 GRADOS EN EL 
22 ;             ;PLANO X/Y
23 FN 0: Q6 =+15 ;GRADUACIÓN EN EL PLANO X/Z
24 ;             ;DEFINE ENTRE CUÁNTOS ELEMENTOS
25 ;             ;LINEALES SE REPARTE EL 
26 ;             ;MOVIMIENTO 3D, EN EL 
27 ;             ;EJE X, Y y Z
28 FN 0: Q7 =+20 ;DISTANCIA DE SEGURIDAD LATERAL
29 ;             ;DISTANCIA ENTRE CUERPO Y 
30 ;             ;HERRAMIENTA EN EL POSICIONAMIENTO
31 ;             ;PREVIO
32 FN 0: Q8 =+3 ;DISTANCIA DE SEGURIDAD EN Z
33 FN 0: Q9 =+2000 ;AVANCE POSICIONAMIENTO PREVIO
34 FN 0: Q10 =+500 ;AVANCE AL PROFUNDIZAR
35 FN 0: Q11 =+800 ;AVANCE DE FRESADO
36 ;Fin de la introducción de parámetros
37 ;
38 BLK FORM 0.1 Z X+0 Y+0 Z-55
39 BLK FORM 0.2  X+110  Y+110  Z+0
40 ;
41 ;Llamada de herramienta fresa cilíndrica
42 TOOL CALL 50 Z S6000
43 ;
44 ;Cálculos
45 FN 4: Q15 =+360 DIV +Q5 ;Paso angular plano X/Y
46 FN 2: Q25 =+Q5 - +1 ;Número de repeticiones plano X/Y
47 FN 4: Q16 =+90 DIV +Q6 ;Paso angular plano X/Z
48 FN 2: Q26 =+Q6 - +1 ;Número de repeticiones plano X/Z
49 FN 1: Q17 =+Q7 + +Q4 ;Posición para el posicionamiento previo
50 FN 1: Q18 =+Q4 + +Q8 ;Posición segura en Z
51 ;Fin de los cálculos
52 ;
53 ;Desplazamiento del punto cero al centro de la esfera
54 CYCL DEF 7.0 NULLPUNKT
55 CYCL DEF 7.1  X+Q1
56 CYCL DEF 7.2  Y+Q2
57 CYCL DEF 7.3  Z+Q3
58 ;
59 ;Posicionamiento previo
60 L  X+Q17  Y+0 R0 FMAX M3
61 L  Z+Q8 R0 FMAX
62 ;
63 L  Y+0  Z+0 R0 FQ10 ;1: profundización
64 LBL 2
65 CC  Z+0  X+Q108
66 L  Y+0 R0 FQ11
67 LP  PR+Q4  PA+90 R0 FQ11 ;Aproximación al contorno
68 LBL 3
69 LP IPA-Q16 FQ11 ;Paso lineal en plano X/Z
70 CALL LBL 3 REPQ26 ;Repetición paso lineal
71 L  Z+Q18 R0 FQ9 ;Desplazarse a la distancia de seguridad
72 L  X+Q17 R0 FQ9 ;Realizar nuevo posicionamiento previo
73 L  Z+0  Y+0 R0 FQ10
74 ;Giro del sistema de coordenadas
75 CYCL DEF 10.0 DREHUNG
76 CYCL DEF 10.1 IROT+Q15
77 CALL LBL 2 REPQ25 ;Repetición trayectoria circular
78 ;Deshacer la transformación de coordenadas
79 CYCL DEF 10.0 DREHUNG
80 CYCL DEF 10.1  ROT+0
81 CYCL DEF 7.0 NULLPUNKT
82 CYCL DEF 7.1  X+0
83 CYCL DEF 7.2  Y+0
84 CYCL DEF 7.3  Z+0
85 ;Retirar la hta. y final del programa
86 L  Z+100 R0 FMAX M30
87 END PGM 7110_es MM