0 BEGIN PGM 7115_es MM 
1 ;Programa para el mecanizado exterior de
2 ;una semiesfera con una fresa toroidal.
3 ;Se fresa en una trayectoria X/Z desde
4 ;abajo hacia arriba. Este movimiento se
5 ;subdivide en trayectorias lineales
6 ;individuales. A continuación se gira el
7 ;sistema de coordenadas y se recorre la
8 ;trayectoria siguiente. Mediante las
9 ;graduaciones definidas se determina la
10 ;precisión y la calidad de la superficie.
11 ;
12 ;Introducción de parámetros
13 FN 0: Q1 =+50 ;CENTRO DE LA ESFERA EN EL EJE X
14 FN 0: Q2 =+50 ;CENTRO DE LA ESFERA EN EL EJE Y
15 FN 0: Q3 =-45 ;CENTRO DE LA ESFERA EN EL EJE Z
16 FN 0: Q4 =+45 ;RADIO ESFERA
17 FN 0: Q5 =+60 ;GRADUACIÓN EN EL PLANO X/Y
18 ;             ;DEFINE ENTRE CUÁNTAS 
19 ;             ;TRAYECTORIAS DE FRESADO SE 
20 ;             ;REPARTEN LOS 360 GRADOS EN EL 
21 ;             ;PLANO X/Y
22 FN 0: Q6 =+15 ;GRADUACIÓN EN EL PLANO X/Z
23 ;             ;DEFINE ENTRE CUÁNTOS ELEMENTOS 
24 ;             ;MOVIMIENTO LINEALES SE REPARTE  
25 ;             ;EL 3D, EN EL EJE X, Y y Z
26 FN 0: Q7 =+20 ;DISTANCIA DE SEGURIDAD LATERAL
27 ;             ;;DISTANCIA ENTRE CUERPO Y 
28 ;             ;HERRAMIENTA EN EL POSICIONAMIENTO
29 ;             ;PREVIO
30 FN 0: Q8 =+3 ;DISTANCIA DE SEGURIDAD EN Z
31 FN 0: Q9 =+2000 ;AVANCE POSICIONAMIENTO PREVIO
32 FN 0: Q10 =+500 ;AVANCE AL PROFUNDIZAR
33 FN 0: Q11 =+800 ;AVANCE DE FRESADO
34 FN 0: Q12 =+5 ;Radio de corte de la herramienta
35 ;Fin de la introducción de parámetros
36 ;
37 BLK FORM 0.1 Z X+0 Y+0 Z-55
38 BLK FORM 0.2  X+100  Y+100  Z+0
39 ;
40 ;Llamada de herramienta fresa toroidal
41 TOOL CALL 119 Z S8000 DL-Q12
42 ;
43 ;Cálculos
Q21 = Q108 - Q12 ;Compensación del radio de cuchilla
44 FN 1: Q19 =+Q4 + +Q12 ;Compensación radio de cuchilla
45 FN 4: Q15 =+360 DIV +Q5 ;Paso angular plano X/Y
46 FN 2: Q25 =+Q5 - +1 ;Número de repeticiones plano X/Y
47 FN 4: Q16 =+90 DIV +Q6 ;Paso angular plano X/Z
48 FN 2: Q26 =+Q6 - +1 ;Número de repeticiones plano X/Z
49 FN 1: Q17 =+Q7 + +Q4 ;Posición para el posicionamiento previo
50 FN 1: Q18 =+Q4 + +Q8 ;Posición segura en Z
51 FN 1: Q18 =+Q18 + +Q12 ;Posición segura en Z
52 ;Fin de los cálculos
53 ;
54 ;Desplazamiento del punto cero al centro de la esfera
55 CYCL DEF 7.0 NULLPUNKT
56 CYCL DEF 7.1  X+Q1
57 CYCL DEF 7.2  Y+Q2
58 CYCL DEF 7.3  Z+Q3
59 ;
60 ;Posicionamiento previo
61 L  X+Q17  Y+0 R0 FMAX M3
62 L  Z+Q18 R0 FMAX
63 ;
64 L  Y+0  Z+0 R0 FQ10 ;1: profundización
65 LBL 2
66 CC  Z+0  X+Q21
67 L  Y+0 R0 FQ11
68 LP  PR+Q19  PA+90 R0 FQ11 ;Aproximación al contorno
69 LBL 3
70 LP IPA-Q16 R0 FQ11 ;Paso lineal en plano X/Z
71 CALL LBL 3 REPQ26 ;Repetición paso lineal
72 L  Z+Q18 R0 FQ9 ;A la distancia de seguridad
73 L  X+Q17 R0 FQ9 ;Realizar nuevo posicionamiento previo
74 L  Y+0  Z+0 R0 FQ10
75 ;Giro del sistema de coordenadas
76 CYCL DEF 10.0 DREHUNG
77 CYCL DEF 10.1 IROT+Q15
78 CALL LBL 2 REPQ25 ;Repetición trayectoria circular
79 ;Deshacer la transformación de coordenadas
80 CYCL DEF 10.0 DREHUNG
81 CYCL DEF 10.1  ROT+0
82 CYCL DEF 7.0 NULLPUNKT
83 CYCL DEF 7.1  X+0
84 CYCL DEF 7.2  Y+0
85 CYCL DEF 7.3  Z+0
86 ;Retirar la hta. y final del programa
87 L  Z+100 R0 FMAX M30
88 END PGM 7115_es MM