0 BEGIN PGM 7125_es MM 
1 ;Programa para el mecanizado exterior de
2 ;una semiesfera con una fresa toroidal.
3 ;El mecanizado tiene lugar en un movimiento
4 ;en forma de espiral. Este movimiento se
5 ;subdivide en movimientos lineales
6 ;individuales. Las graduaciones definen en
7 ;cuántos movimientos lineales se subdivide
8 ;la trayectoria, lo que influye sobre la
9 ;precisión.
10 ;
11 BLK FORM 0.1 Z X-30 Y-30 Z-40
12 BLK FORM 0.2  X+30  Y+30  Z+0
13 ;
14 ;Introducción de parámetros
15 FN 0: Q1 =+0 ;CENTRO DE LA ESFERA EN EL EJE X
16 FN 0: Q2 =+0 ;CENTRO DE LA ESFERA EN EL EJE Y
17 FN 0: Q3 =-30 ;CENTRO DE LA ESFERA EN EL EJE Z
18 FN 0: Q4 =+45 ;GRADUACIÓN VERTICAL
19 ;             ;DEFINE CUÁNTAS TRAYECTORIAS EN 
20 ;             ;ESPIRAL DE 360 GRADOS SE 
21 ;             ;RECORREN DESDE ARRIBA HACIA ABAJO
22 FN 0: Q5 =+180 ;GRADUACIÓN HORIZONTAL
23 ;              ;DEFINE EN CUÁNTAS TRAYECTORIAS 
24 ;              ;LINEALES SE SUBDIVIDE UNA TRAYECTORIA 
25 ;              ;CIRCULAR DE 360 GRADOS.
26 FN 0: Q6 =+30 ;RADIO ESFERA
27 FN 0: Q7 =+90 ;ÁNGULO INICIAL EN LAS VERTICALES
28 FN 0: Q8 =+0 ;ÁNGULO INICIAL EN EL PLANO X/Y
29 FN 0: Q10 =+150 ;AVANCE AL PROFUNDIZAR
30 FN 0: Q11 =+1000 ;AVANCE TRAYECTORIA EN ESPIRAL
31 FN 0: Q13 =+3 ;RADIO DE CORTE DE LA HERRAMIENTA
32 FN 0: Q15 =+2 ;DISTANCIA DE SEGURIDAD
33 FN 0: Q17 =+0 ;ÁNGULO FINAL EN LAS VERTICALES
34 ;Fin de la introducción de parámetros
35 ;
36 ;Llamada de herramienta fresa toroidal
37 TOOL CALL 112 Z S3000 DL-Q13
38 ;
39 ;Posicionamiento previo
40 L  X+Q1  Y+Q2 R0 FMAX M3
41 FN 1: Q16 =+Q15 + +Q13
42 L  Z+Q16 FMAX
43 CALL LBL 1 ;Llamada movimiento en espiral
44 ;
45 ;Final del programa
46 L  Z+100 R0 FMAX M30
47 ;
48 ;Movimiento en espiral
49 LBL 1
Q14 = Q108 - Q13 ;Compensación de radio de hta.
Q26 = Q6 + Q13 ;Radio efectivo hasta el centro de la cuchilla
50 FN 0: Q27 =+Q7 ;Ángulo actual vertical = ángulo inicial vertical
51 FN 0: Q28 =+Q8 ;Ángulo actual plano X/Y = ángulo inicial plano X/Y
Q37 = ( Q17 - Q7 ) / Q4 / Q5 ;Paso angular vertical
Q38 = - 360 / Q5 ;Paso angular plano X/Y
52 CALL LBL 10
53 L  X+Q21  Y+Q22  Z+Q23 R0 FQ10 ;Ir a 1.ª posición
54 ;
55 ;Llamada cálculos, comparación de ángulos y al
56 ;final una trayectoria de círculo completo
57 LBL 2
58 CALL LBL 10
59 L  X+Q21  Y+Q22  Z+Q23 FQ11
60 FN 11: IF +Q27 GT +Q17 GOTO LBL 2
61 CC  X+Q1  Y+Q2
62 CP IPA-360 DR- FQ11
63 LBL 0
64 ;
65 ;Cálculo de posiciones X, Y y Z y nuevos ángulos
66 LBL 10
Q20 = COS Q27 * Q26 + Q14
Q21 = COS Q28 * Q20 + Q1
Q22 = SIN Q28 * Q20 + Q2
Q23 = SIN Q27 * Q26 + Q3
Q27 = Q27 + Q37
Q28 = Q28 + Q38
67 LBL 0
68 END PGM 7125_es MM