0  BEGIN PGM 8090-es MM 
1  ;Programa para registrar puntos de
2  ;coordenadas.
3  ;
4  BLK FORM 0.1 Z  X+0  Y+0  Z-20
5  BLK FORM 0.2  X+100  Y+100  Z+0
6  ;
7  ;Escribir BeginPGM en el registro
8  FN 16: F-PRINT TNC:\Database\BeginPGM.A / surface_data.txt
9  ;
10 ;Llamada de herramienta palpador
11 TOOL CALL 501 Z
12 ;
13 ;Posicionamiento previo
14 FN 0: Q1 =+0 ;COORDENADA DE INICIO EN X PARA EL POSICIONAMIENTO PREVIO
15 FN 0: Q2 =+0.5 ;COORDENADA DE INICIO EN Y
16 LBL 1
17 FN 1: Q1 =+Q1 + +5 ;Nuevo valor en X = valor actual + incremento
18 TCH PROBE 0.0 SUPERF. REF. Q3 Z-
19 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
20 ;
21 ;Escribir los valores en el registro
22 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
23 CALL LBL 1 REP18 ;18 repeticiones, ltima coordenada X+95
24 FN 1: Q2 =+Q2 + +1 ;Incremento en Y
25 LBL 2
26 TCH PROBE 0.0 SUPERF. REF. Q3 Z-
27 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
28 ;
29 ;Escribir los valores en el registro
30 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
31 FN 2: Q1 =+Q1 - +5 ;Incremento en X
32 CALL LBL 2 REP18 ;18 repeticiones, ltima coordenada X+5
33 FN 1: Q2 =+Q2 + +1 ;Incremento en Y
34 CALL LBL 1 REP49 ;49 repeticiones, ltima fila Y+99,5
35 ;
36 ;Escribir EndPGM en el registro
37 FN 16: F-PRINT TNC:\Database\ENDPGM.A / surface_data.txt
38 ;
39 ;Final del programa
40 L  Z+100 R0 FMAX M30
41 END PGM 8090-es MM