0  BEGIN PGM 8125-es MM 
1  ;Contador de piezas.
2  ;En este programa se guarda en una tabla
3  ;el nmero de piezas acabadas, de modo
4  ;que los valores tambin se reducen para
5  ;conservarlos.
6  ;Al inicio del programa debe haberse
7  ;introducido el valor 1 en la
8  ;fila 0 / columna Q1 de la tabla.
9  ;Debe introducirse el nmero de
10 ;repeticiones deseadas al inicio del
11 ;programa. Cuando se inicie el programa,
12 ;se mostrarn en la pantalla el nmero
13 ;de ejecuciones realizadas hasta ese
14 ;momento.
15 ;Cuando se alcance el nmero de
16 ;repeticiones programadas, tambin se
17 ;mostrar en la pantalla. A continuacin,
18 ;se reiniciar a 1 el valor en la tabla.
19 ;
20 ;
21 ;Introduccin de las repeticiones deseadas
22 Q10 = 8 ;NMERO DE REPETICIONES
23 ;
24 ;Abrir la tabla
25 FN 26: TABOPEN TNC:\Database\81251-es.tab
26 ;Leer valor actual de la tabla
27 FN 28: TABREAD Q1 =0 /"Q1"
28 ;
29 FN 0: Q2 =+Q1 ;Copiar el valor
30 Q5 = Q1 - 1 ;Calcular el nmero actual
31 ;
32 ;Mostrar el nmero actual de repeticiones
33 FN 16: F-PRINT TNC:\Database\81252-es.a / Screen:
34 ;
35 Q1 = Q1 + 1 ;Seguir sincronizando el temporizador
36 ;
37 ;
38 ;Ejecucin del mecanizado deseado. Puede
39 ;realizarse con PGM CALL, pero de esta
40 ;forma el programa llamado no puede
41 ;contener M2 o M30
42 CALL PGM TNC:\Database\81254-es.h
43 STOP
44 ;
45 ;
46 ;Comparacin de si se ha alcanzado el
47 ;nmero de repeticiones
48 FN 12: IF +Q2 LT +Q10 GOTO LBL 99
49 ;Visualizacin de si se ha alcanzado el
50 ;nmero de repeticiones.
51 FN 16: F-PRINT TNC:\Database\81253-es.a / Screen:
52 ;
53 Q1 = 1 ;Reiniciar el contador
54 ;Escribir el valor del contador en la tabla
55 FN 27: TABWRITE 0 /"Q1" = Q1
56 ;Final del programa
57 STOP
58 M30
59 ;
60 ;Label si se necesitan repeticiones
61 ;adicionales
62 LBL 99
63 ;Escribir el valor del contador en la tabla
64 FN 27: TABWRITE 0 /"Q1" = Q1
65 ;Final del programa
66 M30
67 END PGM 8125-es MM