0  BEGIN PGM 82251_ES MM 
1  ;Programa NC para volver a calcular el
2  ;contador, leer la hora actual y
3  ;compararla con la hora definida por
4  ;usted en el programa 8220_es.h.
5  ;Si se alcanza o sobrepasa la hora
6  ;definida por usted, el control
7  ;numérico reinicia el contador a cero
8  ;automáticamente.
9  ;
10 ;Aumentar en uno el valor del contador
11 QR1 = QR1 + 1
12 ;
13 ;Leer la hora actual y guardarla en QS1
14 QS1 = SYSSTR( ID321 NR13 )
15 ;
16 ;Separar las horas de QS1 y guardarlas en QS20
17 QS20 = SUBSTR( SRC_QS1 BEG0 LEN2 )
18 ;
19 ;Separar los minutos de QS1 y guardarlos en QS21
20 QS21 = SUBSTR( SRC_QS1 BEG3 LEN2 )
21 ;
22 ;Transformar en números la secuencia de caracteres
23 ;de QS20 y guardarla en QL20 (horas)
24 QL20 = TONUMB( SRC_QS20 )
25 ;
26 ;Transformar en números la secuencia de caracteres
27 ;de QS21 y guardarla en QL21 (minutos)
28 QL21 = TONUMB( SRC_QS21 )
29 ;
30 ;Comprobar si se han alcanzado las horas para el reinicio
31 FN 11: IF +QL20 GT +QR10 GOTO LBL "RESET"
32 FN 12: IF +QL20 LT +QR10 GOTO LBL "NOT_RESET"
33 ;
34 ;Comprobar si se han alcanzado los minutos para el reinicio
35 FN 12: IF +QL21 LT +QR11 GOTO LBL "NOT_RESET"
36 ;
37 ;Reiniciar el contador
38 LBL "RESET"
39 QR1 = 0
40 ;
41 STOP
42 LBL "NOT_RESET"
43 END PGM 82251_ES MM