0  BEGIN PGM 8230_ES MM 
1  ;Programa NC para medir con exactitud la
2  ;coordenada Z en posiciones de mecanizado
3  ;definidas en una tabla de puntos e
4  ;introducirla en la tabla. A continuación,
5  ;se define la tabla de puntos de
6  ;referencia como Pattern y el control
7  ;numérico ejecuta un ciclo de mecanizado
8  ;definido en las posiciones.
9  ;La coordenada Z introducida en la tabla
10 ;define el punto inicial del ciclo, de
11 ;forma que la profundidad definida en el
12 ;ciclo siempre se refiere a la coordenada
13 ;Z medida previamente.
14 ;
15 BLK FORM 0.1 Z X-25 Y-25 Z-50
16 BLK FORM 0.2  X+25  Y+25  Z+0
17 ;
18 ;Medir
19 ;Llamada de herramienta Sistema de palpación
20 TOOL CALL "TOUCH_PROBE" Z
21 ;
22 ;Abrir tabla
23 FN 26: TABOPEN 82301_es.PNT
24 ;
25 Q52 = 5 ;NÚMERO DE POSICIONES QUE SE VAN A MEDIR
26 CALL LBL "MEASURE" ;Llamada de subprograma Medición
27 ;
28 ;Mecanizar
29 ;Llamada de herramienta Broca
30 TOOL CALL "DRILL_D8.5" Z S9000 F2500
31 M3
32 CYCL DEF 200 TALADRADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q201=-2    ;PROFUNDIDAD ~
    Q206= AUTO ;AVANCE PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q210=+0    ;TIEMPO ESPERA ARRIBA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q211=+0    ;TIEMPO ESPERA ABAJO ~
    Q395=+1    ;REFER. PROF.
33 SEL PATTERN "82301_es.PNT"
34 L  X+0  Y+0  Z+50 R0 FMAX
35 CYCL CALL PAT FMAX
36 ;
37 CALL LBL "SAFE" ;Ir a posición segura
38 ;
39 ;Final del programa
40 M30
41 ;
42 ;Subprogramas
43 ;Ir a posición segura
44 LBL "SAFE"
45 M140 MB MAX F9999
46 L  X+0  Y+0 R0 FMAX M91
47 LBL 0
48 ;
49 ;Subprograma Medición
50 LBL "MEASURE"
51 Q50 = 0 ;Primera fila
52 Q51 = Q52 - 1 ;Cálculo para el número de repeticiones
53 LBL "LOOP"
54 ;Leer coordenadas XY para la medición
55 FN 28: TABREAD Q55 =Q50 /"X,Y"
56 TCH PROBE 427 MEDIR COORDENADA ~
    Q263=+Q55  ;1ER PUNTO EN EJE 1 ~
    Q264=+Q56  ;1ER PUNTO EN EJE 2 ~
    Q261=+0    ;ALTURA MEDIDA ~
    Q320=+5    ;DISTANCIA SEGURIDAD ~
    Q272=+3    ;EJE DE MEDICION ~
    Q267=-1    ;DIREC DESPLAZAMIENTO ~
    Q260=+15   ;ALTURA DE SEGURIDAD ~
    Q281=+0    ;PROTOCOLO MEDIDA ~
    Q288=+0    ;TAMANO MAXIMO ~
    Q289=+0    ;TAMANO MINIMO ~
    Q309=+0    ;PARO PGM SI ERROR ~
    Q330=+0    ;HERRAMIENTA ~
    Q498=+0    ;INVERTIR HERRAMIENTA ~
    Q531=+0    ;ANGULO DE INCIDENCIA
57 ;Guardar en el fichero oculto el resultado de medición en Z
58 FN 27: TABWRITE Q50 /"Z" = Q160
59 Q50 = Q50 + 1 ;Aumentar número de fila
60 CALL LBL "LOOP" REPQ51
61 LBL 0
62 END PGM 8230_ES MM