0  BEGIN PGM 8235_ES MM 
1  ;Programa NC para medir con exactitud la
2  ;coordenada Z en posiciones de mecanizado
3  ;definidas en una tabla de puntos e
4  ;introducirla en la tabla.
5  ;En este programa de ejemplo, el control
6  ;numérico ejecuta la rutina de medición
7  ;en cinco caras de un cubo.
8  ;A continuación, se define para cada
9  ;cara la tabla de puntos de referencia
10 ;correspondiente como Pattern y el
11 ;control numérico ejecuta un ciclo de
12 ;mecanizado definido en las posiciones.
13 ;La coordenada Z introducida en la
14 ;tabla define el punto inicial del
15 ;ciclo, de forma que la profundidad
16 ;definida en el ciclo siempre se
17 ;refiere a la coordenada Z medida
18 ;previamente.
19 ;
20 BLK FORM 0.1 Z X-25 Y-25 Z-50
21 BLK FORM 0.2  X+25  Y+25  Z+0
22 ;
23 ;MEDIR
24 ;
25 ;Llamada de herramienta Sistema de palpación
26 TOOL CALL "TOUCH_PROBE" Z
27 ;
28 ;Página 1
29 PLANE RESET STAY ;Anular la inclinación
30 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Decalaje del punto cero
31 ;Llamada de subprograma para aproximar a una posición segura
32 CALL LBL "SAFE"
33 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Inclinar el plano de mecanizado
34 ;
35 ;Abrir la tabla de puntos de la cara 1
36 FN 26: TABOPEN 82351.PNT
37 Q52 = 1 ;NÚMERO DE POSICIONES
38 ;Llamada de subprograma para medir
39 CALL LBL "MEASURE"
40 ;
41 ;Página 2
42 PLANE RESET STAY ;Anular la inclinación
43 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Decalaje del punto cero
44 ;Llamada de subprograma para aproximar a una posición segura
45 CALL LBL "SAFE"
46 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Inclinar el plano de mecanizado
47 ;
48 ;Abrir la tabla de puntos de la cara 2
49 FN 26: TABOPEN 82352.PNT
50 Q52 = 2 ;NÚMERO DE POSICIONES
51 ;Llamada de subprograma para medir
52 CALL LBL "MEASURE"
53 ;
54 ;Página 3
55 PLANE RESET STAY ;Anular la inclinación
56 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Decalaje del punto cero
57 ;Llamada de subprograma para aproximar a una posición segura
58 CALL LBL "SAFE"
59 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Inclinar el plano de mecanizado
60 ;
61 ;Abrir la tabla de puntos de la cara 3
62 FN 26: TABOPEN 82353.PNT
63 Q52 = 3 ;NÚMERO DE POSICIONES
64 ;Llamada de subprograma para medir
65 CALL LBL "MEASURE"
66 ;
67 ;Página 4
68 PLANE RESET STAY ;Anular la inclinación
69 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Decalaje del punto cero
70 ;Llamada de subprograma para aproximar a una posición segura
71 CALL LBL "SAFE"
72 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Inclinar el plano de mecanizado
73 ;
74 ;Abrir la tabla de puntos de la cara 4
75 FN 26: TABOPEN 82354.PNT
76 Q52 = 4 ;NÚMERO DE POSICIONES
77 ;Llamada de subprograma para medir
78 CALL LBL "MEASURE"
79 ;
80 ;Página 5
81 PLANE RESET STAY ;Anular la inclinación
82 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Decalaje del punto cero
83 ;Llamada de subprograma para aproximar a una posición segura
84 CALL LBL "SAFE"
85 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Inclinar el plano de mecanizado
86 ;
87 ;Abrir la tabla de puntos de la cara 5
88 FN 26: TABOPEN 82355.PNT
89 Q52 = 5 ;NÚMERO DE POSICIONES
90 ;Llamada de subprograma para medir
91 CALL LBL "MEASURE"
92 ;
93 ;MECANIZAR
94 ;
95 ;Llamada de herramienta Broca
96 TOOL CALL "DRILL_D8.5" Z S9000 F2500
97 M3
98 CYCL DEF 200 TALADRADO ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q201=-2    ;PROFUNDIDAD ~
    Q206= AUTO ;AVANCE PROFUNDIDAD ~
    Q202=+5    ;PASO PROFUNDIZACION ~
    Q210=+0    ;TIEMPO ESPERA ARRIBA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD ~
    Q211=+0    ;TIEMPO ESPERA ABAJO ~
    Q395=+1    ;REFER. PROF.
99 ;
100 ;Página 1
101 PLANE RESET STAY ;Anular la inclinación
102 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Decalaje del punto cero
103 ;Llamada de subprograma para aproximar a una posición segura
104 CALL LBL "SAFE"
105 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Inclinación del plano de mecanizado
106 ;
107 ;Definición de la tabla de puntos de la cara 1 como patrón de puntos
108 SEL PATTERN "82351.PNT"
109 ;Llamada a subprograma para el mecanizado
110 CALL LBL "MACHINING"
111 ;
112 ;Página 2
113 PLANE RESET STAY ;Anular la inclinación
114 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Decalaje del punto cero
115 ;Llamada de subprograma para aproximar a una posición segura
116 CALL LBL "SAFE"
117 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Inclinación del plano de mecanizado
118 ;
119 ;Definición de la tabla de puntos de la cara 2 como patrón de puntos
120 SEL PATTERN "82352.PNT"
121 ;Llamada a subprograma para el mecanizado
122 CALL LBL "MACHINING"
123 ;
124 ;Página 3
125 PLANE RESET STAY ;Anular la inclinación
126 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Decalaje del punto cero
127 ;Llamada de subprograma para aproximar a una posición segura
128 CALL LBL "SAFE"
129 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Inclinación del plano de mecanizado
130 ;
131 ;Definición de la tabla de puntos de la cara 3 como patrón de puntos
132 SEL PATTERN "82353.PNT"
133 ;Llamada a subprograma para el mecanizado
134 CALL LBL "MACHINING"
135 ;
136 ;Página 4
137 PLANE RESET STAY ;Anular la inclinación
138 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Decalaje del punto cero
139 ;Llamada de subprograma para aproximar a una posición segura
140 CALL LBL "SAFE"
141 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Inclinación del plano de mecanizado
142 ;
143 ;Definición de la tabla de puntos de la cara 4 como patrón de puntos
144 SEL PATTERN "82354.PNT"
145 ;Llamada a subprograma para el mecanizado
146 CALL LBL "MACHINING"
147 ;
148 ;Página 5
149 PLANE RESET STAY ;Anular la inclinación
150 ;Nullpunktverschiebung
151 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Decalaje del punto cero
152 ;Llamada de subprograma para aproximar a una posición segura
153 CALL LBL "SAFE"
154 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Inclinación del plano de mecanizado
155 ;
156 ;Definición de la tabla de puntos de la cara 5 como patrón de puntos
157 SEL PATTERN "82355.PNT"
158 ;Llamada a subprograma para el mecanizado
159 CALL LBL "MACHINING"
160 ;
161 ;Llamada de subprograma para aproximar a una posición segura
162 CALL LBL "SAFE"
163 PLANE RESET TURN FMAX ;Anular la inclinación
164 ;
165 ;Final del programa
166 M30
167 ;
168 ;Subprogramas
169 ;Desplazar a una posición segura en función de la máquina
170 LBL "SAFE"
171 M140 MB MAX F9999
172 L  Z+0 R0 FMAX M91
173 L  X+0  Y+0 R0 FMAX M91
174 LBL 0
175 ;
176 ;Medir
177 LBL "MEASURE"
178 Q50 = 0 ;Primera fila
179 Q51 = Q52 - 1 ;Cálculo para el número de repeticiones
180 LBL "LOOP"
181 ;Leer coordenadas XY para la medición
182 FN 28: TABREAD Q55 =Q50 /"X,Y"
183 TCH PROBE 427 MEDIR COORDENADA ~
    Q263=+Q55  ;1ER PUNTO EN EJE 1 ~
    Q264=+Q56  ;1ER PUNTO EN EJE 2 ~
    Q261=+0    ;ALTURA MEDIDA ~
    Q320=+5    ;DISTANCIA SEGURIDAD ~
    Q272=+3    ;EJE DE MEDICION ~
    Q267=-1    ;DIREC DESPLAZAMIENTO ~
    Q260=+15   ;ALTURA DE SEGURIDAD ~
    Q281=+0    ;PROTOCOLO MEDIDA ~
    Q288=+0    ;TAMANO MAXIMO ~
    Q289=+0    ;TAMANO MINIMO ~
    Q309=+0    ;PARO PGM SI ERROR ~
    Q330=+0    ;HERRAMIENTA ~
    Q498=+0    ;INVERTIR HERRAMIENTA ~
    Q531=+0    ;ANGULO DE INCIDENCIA
184 ;Guardar en el fichero oculto el resultado de medición en Z
185 FN 27: TABWRITE Q50 /"Z" = Q160
186 Q50 = Q50 + 1 ;Aumentar número de fila
187 CALL LBL "LOOP" REPQ51
188 LBL 0
189 ;
190 ;Mecanizado
191 LBL "MACHINING"
192 L  X+0  Y+0  Z+50 R0 FMAX ;Posicionamiento previo
193 CYCL CALL PAT FMAX ;Llamar al ciclo en las posiciones de la tabla de puntos
194 LBL 0
195 END PGM 8235_ES MM