0 BEGIN PGM 8245_ES MM 
1 ;Programa NC, para determinar mediante el sistema de
2 ;palpación los valores de corrección para la opción
3 ;ToolComp 3D (opción #92) y escribir en la tabla 3DTC.
4 ;Antes de la ejecución del programa, es imprescindible
5 ;crear la tabla e introducir el número de líneas
6 ;necesarias. En la columna Ángulo, se definen los
7 ;valores angulares, en los cuales el control numérico
8 ;mide el radio.
9 ;Es imprescindible definir la ruta de la tabla en la
10 ;función FN 26.
11 ;Al inicio del programa, el control numérico efectúa
12 ;una llamada a un programa NC, mediante el cual en
13 ;una arista de la pieza de trabajo se fresa un radio
14 ;de 5 mm.
15 ;A continuación, mediante el ciclo 444 el control
16 ;numérico mide puntos del radio.
17 ;Para ello, en primer lugar el control numérico obtiene
18 ;el ángulo definido de la tabla, y a partir del mismo
19 ;calcula las coordenadas y la normal de los puntos de
20 ;medición.
21 ;Deberá tenerse en cuenta que antes de la medición
22 ;mediante el ciclo 444, es imprescindible que el sistema
23 ;de palpación esté calibrado en 3D con el ciclo 460.
24 ;El control numérico escribe el valor de corrección
25 ;medido en la tabla.
26 ;En el Block Scan y en el Test del programa, el control
27 ;numérico omite la medición y escritura de parte del
28 ;programa, a fin de evitar que se escriban valores
29 ;erróneos.
30 ;Una vez medidos todos los puntos y escritos todos los
31 ;valores en la tabla, el control numérico salta al final
32 ;del programa. En el programa de ejemplo, se efectúa la
33 ;llamada a dos programas NC adicionales. En el primer
34 ;programa, en la arista de la pieza de trabajo el
35 ;control numérico efectúa el acabado de una pieza
36 ;adicional de radio 5 mm. A este respecto, se debe
37 ;tener en cuenta que la herramienta de acabado esté
38 ;asignada a la tabla de valores de corrección.
39 ;En el programa NC que sigue a continuación, el control
40 ;numérico mide de nuevo puntos del radio, de modo que
41 ;mediante el protocolo de medición se pueda comprobar si
42 ;la corrección tiene efecto.
43 ;
44 BLK FORM 0.1 Z X-50 Y+0 Z-50
45 BLK FORM 0.2  X+0  Y+50  Z+0
46 ;
47 ;Llamada al programa para fresar el radio
48 CALL PGM 82451_es.h
49 ;
50 ;Abrir la tabla en la que se describe el resultado de
51 ;la medición
52 FN 26: TABOPEN TNC:\system\3D-ToolComp\TAB_8245.3DTC
53 ;
54 ;Parámetros de introducción
QL20 = 0 ;PRIMERA LÍNEA DE LA TABLA
QL21 = 8 ;NÚMERO DE LÍNEAS DE LA TABLA
QL22 = 5 ;RADIO QUE SE VA A MEDIR
QL2 = 3 ;POSICIÓN DE MEDIDA EN EL EJE Y
55 ;Fin de la introducción de parámetros
56 ;
57 ;Cálculos
QL23 = QL21 - 1 ;Número de repeticiones
58 ;Fin de los cálculos
59 ;
60 ;Volver a establecer la inclinación del plano de mecanizado
61 PLANE RESET STAY
62 ;Retirar la hta.
63 M140 MB MAX
64 ;
65 ;Llamada de herramienta Sistema de palpación
66 TOOL CALL "TOUCH_PROBE" Z S11
67 ;
68 ;Inclinar el plano de mecanizado
69 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN MB MAX FMAX SEQ-
70 ;
71 ;Posicionamiento previo
72 L  X+0  Y+0 R0 FMAX
73 L  Z+25 R0 FMAX
74 ;
75 ;Repetición
76 LBL "REPETITION"
77 ;Llamada de subprograma CALC
78 CALL LBL "CALC"
79 ;Llamada de subprograma PROBE
80 CALL LBL "PROBE"
81 ;Llamada de repetición
82 CALL LBL "REPETITION" REPQL23
83 ;
84 ;Salto al final del programa
85 FN 9: IF +0 EQU +0 GOTO LBL "End"
86 ;
87 ;Subprograma Medición
88 LBL "PROBE"
89 FN 18: SYSREAD QL40 = ID992 NR10 ;Comprobar si la ejecución hasta una frase está activa
90 FN 9: IF +QL40 EQU +1 GOTO LBL "JUMP" ;Si la ejecución hasta una frase está activa, llevar a cabo un salto
91 FN 18: SYSREAD QL41 = ID992 NR16 ;Comprobar si la simulación está activa
92 FN 9: IF +QL41 EQU +0 GOTO LBL "JUMP" ;Si la simulación está activa, llevar a cabo un salto
93 TCH PROBE 444 PALPAR 3D ~
    Q263=+QL1  ;1ER PUNTO EN EJE 1 ~
    Q264=+QL2  ;1ER PUNTO EN EJE 2 ~
    Q294=+QL3  ;1ER PUNTO EJE 3 ~
    Q581=+QL11 ;NORMAL EJE PRINCIPAL ~
    Q582=+QL12 ;NORMAL EJE AUXILIAR ~
    Q583=+QL13 ;NORMAL EJE HERRAM. ~
    Q320=+2    ;DISTANCIA SEGURIDAD ~
    Q260=+25   ;ALTURA DE SEGURIDAD ~
    QS400="0.015-0.015" ;TOLERANCIA ~
    Q309=+0    ;REACCION AL ERROR
QL50 = - Q164 ;Transformar el resultado de la medición en un valor de corrección
94 FN 27: TABWRITE QL20 /"DR2" = QL50 ;Escribir el valor de corrección en la tabla
QL20 = QL20 + 1 ;Seguir con el cálculo del número de fila
95 ;Marca de salto para la omisión de la medición 
96 LBL "JUMP"
97 LBL 0
98 ;Calcular el subprograma
99 LBL "CALC"
100 FN 28: TABREAD QL60 =QL20 /"ANGLE" ;Obtener el ángulo de la tabla
QL61 = ( SIN QL60 ) * QL22 ;Calcular la coordenada X del punto
QL1 = - QL22 + QL61 ;Calcular la coordenada X del punto
QL62 = COS QL60 * QL22 ;Calcular la coordenada Z del punto
QL3 = - QL22 + QL62 ;Calcular la coordenada Z del punto
QL11 = SIN QL60 * 1 ;Calcular la normal en el eje principal
QL12 = 0 ;Definir la normal del eje auxiliar
QL13 = COS QL60 * 1 ;Calcular la normal del eje de la herramienta
101 LBL 0
102 ;
103 ;Final del programa
104 LBL "End"
105 ;Efectuar la llamada del programa NC para la superficie corregida
106 CALL PGM 82452_es.h
107 ;Efectuar la llamada del programa NC para la medición
108 CALL PGM 82453_es.h
109 M129 M9
110 M30
111 END PGM 8245_ES MM