0 BEGIN PGM 9040_ES MM 
1 ;Programa NC para determinar automáticamente
2 ;el nombre del fichero y, mediante el ciclo,
3 ;grabarlo en la pieza.
4 ;Con una función de cadena, el control numérico
5 ;lee con el ID correspondiente la ruta del
6 ;programa y la guarda en el QS1. A continuación
7 ;llama otro programa en el que selecciona de
8 ;la ruta el nombre del fichero.
9 ;El nombre del fichero lo vuelve a entregar
10 ;entonces en el parámetro QS1 al programa a
11 ;llamar. Allí lo utiliza entonces como texto de
12 ;grabado en el ciclo 225.
13 ;Si los ficheros empleados no están en el mismo
14 ;directorio, deberán adaptarse los datos de la
15 ;ruta en la llamada.
16 ;
17 BLK FORM 0.1 Z X+0 Y+0 Z-20
18 BLK FORM 0.2  X+100  Y+100  Z+0
19 ;
20 ;Llamada a la herramienta, herramienta de grabado
21 TOOL CALL 151 Z S10000
22 ;
23 ;Retirar la hta.
24 L  Z+100 R0 FMAX M3
25 ;
26 ;Mediante ID10010 NR1 leer ruta del fichero y guardarla
27 ;en el QS1
QS1 = SYSSTR( ID10010 NR1 )
28 ;
29 ;Llamar el programa para seleccionar de la ruta el nombre
30 ;del fichero
31 CALL PGM 90401_es.H
32 ;
33 ;Grabar el nombre del fichero que está en el QS1
34 CYCL DEF 225 GRABAR ~
   QS500= QS1     ;TEXTO DE GRABADO ~
    Q513=+8    ;ALTURA CARACTER ~
    Q514=+0    ;FACTOR DISTANCIA ~
    Q515=+0    ;TIPO LETRA ~
    Q516=+0    ;POS. TEXTO ~
    Q374=+0    ;ANGULO GIRO ~
    Q517=+50   ;RADIO CIRCULO ~
    Q207=+2000 ;AVANCE DE FRESADO ~
    Q201=-0.1  ;PROFUNDIDAD ~
    Q206=+150  ;AVANCE PROFUNDIDAD ~
    Q200=+2    ;DISTANCIA SEGURIDAD ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2A DIST. SEGURIDAD
35 L  X+20  Y+40 R0 FMAX M99
36 ;
37 ;Retirar la hta.
38 L  Z+100 R0 FMAX
39 ;
40 ;Final del programa
41 M30
42 END PGM 9040_ES MM